From 416917195d2c0945a5477eae4b21564fd4bfe204 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 31 Oct 2025 08:29:25 +0100
Subject: [PATCH] dev-python/pbr: Bump to 7.0.2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pbr/Manifest         |  1 +
 dev-python/pbr/pbr-7.0.2.ebuild | 70 +++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)
 create mode 100644 dev-python/pbr/pbr-7.0.2.ebuild

diff --git a/dev-python/pbr/Manifest b/dev-python/pbr/Manifest
index 042fe63d49fce..d561b6bfc5658 100644
--- a/dev-python/pbr/Manifest
+++ b/dev-python/pbr/Manifest
@@ -1 +1,2 @@
 DIST pbr-7.0.1.tar.gz 130086 BLAKE2B e29b94fcd2a0316aac2c5a918d2f94607f50c77225e5535da0381e61e41f05cea01341e77547316816963cda235fed356cf6ffd87c5faf0f2c47ff99122a4d8b SHA512 79e204e81f1ca5c74fdfab3df007e394f0248761c1464c1ffab270347d3c2e25b1aba331be153bdfa4a6fad152a39574df5fffd39051b0242af3cdf05ef454c8
+DIST pbr-7.0.2.tar.gz 134192 BLAKE2B 44bd6b522cbcbd7ea23aabd5baec854812f61a5ad3323bd63afbf85c94b59c01a4638a6a21fb4f39046ddd20997d5dd39c31112a36ca35c86bf01dc4b6a14917 SHA512 ee0b9928f0a025b7e645beef49dad27ae95c9cb6b0e8b94df090c8298659c950d7214a9979af5b66b20947f06705eeb0114a55390d62b759f382c5b85aa11b0c
diff --git a/dev-python/pbr/pbr-7.0.2.ebuild b/dev-python/pbr/pbr-7.0.2.ebuild
new file mode 100644
index 0000000000000..42572748bb44b
--- /dev/null
+++ b/dev-python/pbr/pbr-7.0.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3_11 python3_{11..14} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
+HOMEPAGE="
+	https://opendev.org/openstack/pbr/
+	https://github.com/openstack/pbr/
+	https://pypi.org/project/pbr/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/setuptools-64.0.0[${PYTHON_USEDEP}]
+"
+
+# git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and
+# https://bugs.gentoo.org/show_bug.cgi?id=561038 docutils is needed for sphinx
+# exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848 stestr is run as
+# external tool.
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+			>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+			>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+			>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+			>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20.0.3[${PYTHON_USEDEP}]
+			dev-vcs/git
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# TODO: investigate
+	sed -e 's:test_with_argument:_&:' \
+		-e 's:test_wsgi_script_run:_&:' \
+		-i pbr/tests/functional/test_wsgi_scripts.py || die
+	# installs random packages via pip from the Internet
+	rm pbr/tests/functional/test_pep517.py || die
+	rm pbr/tests/functional/test_requirements.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Testing on ${EPYTHON} is not supported at the moment"
+		return
+	fi
+
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest -b
+}