diff --git a/gui-apps/sddm-gentoo-config/metadata.xml b/gui-apps/sddm-gentoo-config/metadata.xml
new file mode 100644
index 0000000000000..0340d05f52eba
--- /dev/null
+++ b/gui-apps/sddm-gentoo-config/metadata.xml
@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>lxqt@gentoo.org</email>
+		<name>LXQt</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>kde@gentoo.org</email>
+		<name>Gentoo KDE Project</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="gentoo">gentoo</remote-id>
+		<bugs-to>http://bugs.gentoo.org</bugs-to>
+	</upstream>
+	<use>
+		<flag name="kwin">KWin DisplayServer support (EXPERIMENTAL)</flag>
+		<flag name="weston">Weston DisplayServer support (EXPERIMENTAL)</flag>
+	</use>
+</pkgmetadata>
diff --git a/gui-apps/sddm-gentoo-config/sddm-gentoo-config-0.ebuild b/gui-apps/sddm-gentoo-config/sddm-gentoo-config-0.ebuild
new file mode 100644
index 0000000000000..583d9cbeacd62
--- /dev/null
+++ b/gui-apps/sddm-gentoo-config/sddm-gentoo-config-0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2025-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Gentoo defaults for SDDM (Simple Desktop Display Manager)"
+HOMEPAGE="https://wiki.gentoo.org/wiki/SDDM"
+SRC_URI=""
+S=${WORKDIR}
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="kwin systemd weston"
+REQUIRED_USE="?? ( kwin weston )"
+
+RDEPEND="
+	!<x11-misc/sddm-0.21.0_p20250818
+	kwin? ( kde-plasma/kwin:6 )
+	weston? ( dev-libs/weston[kiosk] )
+	!kwin? ( !weston? ( x11-base/xorg-server ) )
+"
+
+GEN2CONF=01gentoo.conf
+
+src_prepare() {
+	touch "${T}"/${GEN2CONF} || die
+
+	_displayserver() {
+		if use kwin || use weston; then
+			echo "wayland"
+		else
+			echo "x11"
+		fi
+	}
+
+	_compositorcommand() {
+		local cc=()
+		if use kwin; then
+			cc=( kwin_wayland --drm )
+			has_version "kde-plasma/kwin[lock]" && cc+=( --no-lockscreen )
+			has_version "kde-plasma/kwin[shortcuts]" && cc+=( --no-global-shortcuts )
+			use systemd && cc+=( --locale1 )
+		else
+			cc=( weston --shell=kiosk )
+		fi
+		echo "${cc[@]}"
+	}
+
+	cat >> "${T}"/${GEN2CONF} <<- _EOF_ || die
+		[General]
+		# Remove qtvirtualkeyboard as InputMethod default
+		InputMethod=
+
+		# Which display server should be used
+		DisplayServer=$(_displayserver)
+	_EOF_
+
+	if use kwin; then
+		cat >> "${T}"/${GEN2CONF} <<- _EOF_ || die
+
+			GreeterEnvironment=QT_WAYLAND_SHELL_INTEGRATION=layer-shell
+
+			[Wayland]
+			CompositorCommand=$(_compositorcommand)
+		_EOF_
+	fi
+
+	default
+}
+
+src_install() {
+	insinto /etc/sddm.conf.d/
+	doins "${T}"/${GEN2CONF}
+}
diff --git a/profiles/arch/powerpc/ppc64/package.use.mask b/profiles/arch/powerpc/ppc64/package.use.mask
index 8b843d1f211a0..75c8584f8028d 100644
--- a/profiles/arch/powerpc/ppc64/package.use.mask
+++ b/profiles/arch/powerpc/ppc64/package.use.mask
@@ -1,6 +1,10 @@
 # Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
+# Andreas Sturmlechner <asturm@gentoo.org> (2025-10-08)
+# dev-libs/weston is not stable.
+gui-apps/sddm-gentoo-config weston
+
 # Michał Górny <mgorny@gentoo.org> (2025-09-12)
 # These BLAS/LAPACK providers are keyworded here.
 sci-libs/flexiblas -blis
diff --git a/x11-misc/sddm/sddm-0.21.0_p20251101.ebuild b/x11-misc/sddm/sddm-0.21.0_p20251101.ebuild
index 2201e27002ab6..1601ac42a03c3 100644
--- a/x11-misc/sddm/sddm-0.21.0_p20251101.ebuild
+++ b/x11-misc/sddm/sddm-0.21.0_p20251101.ebuild
@@ -48,7 +48,6 @@ RDEPEND="${DEPEND}
 "
 BDEPEND="
 	dev-python/docutils
-	>=dev-build/cmake-3.25.0
 	>=dev-qt/qttools-${QTMIN}[linguist]
 	kde-frameworks/extra-cmake-modules:0
 	virtual/pkgconfig