diff --git a/dev-python/docker/Manifest b/dev-python/docker/Manifest
index 1e77cd1696ad6..4d881e4c47264 100644
--- a/dev-python/docker/Manifest
+++ b/dev-python/docker/Manifest
@@ -1 +1,2 @@
 DIST docker-py-7.1.0.gh.tar.gz 253282 BLAKE2B 82eba285c1ea61956005dd0a9bfb66864fd30119a4b4c384d0d4350edeb331004d66bcdba6f20ec56ff48590b4a29a7b0fb07c6db6ecadfe96830337c37a535a SHA512 3dd73f2c3f3e92863496ef8277f481e64484e0e85a64dffe4e3287836823e4b118a5c8e73b2540e7188a0b755cd3f237ccc868a5bfb81d3bff1142fbb33755cb
+DIST docker-py-7.2.0.gh.tar.gz 255679 BLAKE2B 1a1d32ceb56f74a5c81f2e6fea5e6def76d442f79489c10ce2a7f8cac40fcc6089dcb049c31406ccd43267b7c45114fd751a762812e03aaacfe38f728cd1a422 SHA512 a4baaaf7850a51d7ca4ae71084b9bfa9d8f65bef3e1ba9d739f86aefac6319ca87d71e081d049f6bfa1e7ceec70395bcf309904aa316c911f7998b043aeb98bd
diff --git a/dev-python/docker/docker-7.2.0.ebuild b/dev-python/docker/docker-7.2.0.ebuild
new file mode 100644
index 0000000000000..da34df41d9d5b
--- /dev/null
+++ b/dev-python/docker/docker-7.2.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1
+
+MY_P=docker-py-${PV}
+DESCRIPTION="Python client for Docker"
+HOMEPAGE="
+	https://github.com/docker/docker-py/
+	https://pypi.org/project/docker/
+"
+SRC_URI="
+	https://github.com/docker/docker-py/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/paramiko-2.4.3[${PYTHON_USEDEP}]
+		>=dev-python/websocket-client-1.3.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/myst-parser'
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	# localhost has a better chance of being in /etc/hosts
+	sed -e 's:socket[.]gethostname():"localhost":' \
+		-i tests/unit/api_test.py || die
+
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local -x TZ=UTC
+	epytest tests/unit
+}