diff --git a/dev-python/pyzstd/Manifest b/dev-python/pyzstd/Manifest
new file mode 100644
index 0000000000000..a90baf8edcf1b
--- /dev/null
+++ b/dev-python/pyzstd/Manifest
@@ -0,0 +1 @@
+DIST pyzstd-0.17.0.tar.gz 1212160 BLAKE2B df758d02d4cb8df504538b0ff9de059a86d15ca1fe362879932f916db9ac057eaa34efb342fcca9c206a8f463201b8f774978727c209cd8799e51152b7ff90c0 SHA512 932bd4b7df026c40aa24c1548237b3decf44109897572b8933d4a2284036998d7bb320d355a71f9ab04509333204072ed78098f6e6c05b997a80f268763a4b28
diff --git a/dev-python/pyzstd/metadata.xml b/dev-python/pyzstd/metadata.xml
new file mode 100644
index 0000000000000..0176581a324f1
--- /dev/null
+++ b/dev-python/pyzstd/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">Rogdham/pyzstd</remote-id>
+		<remote-id type="pypi">pyzstd</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/pyzstd/pyzstd-0.17.0.ebuild b/dev-python/pyzstd/pyzstd-0.17.0.ebuild
new file mode 100644
index 0000000000000..465f69cdb23bb
--- /dev/null
+++ b/dev-python/pyzstd/pyzstd-0.17.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_UPSTREAM_PEP517=standalone
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python bindings to Zstandard (zstd) compression library"
+HOMEPAGE="
+	https://github.com/Rogdham/pyzstd/
+	https://pypi.org/project/pyzstd/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	app-arch/zstd:=
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.11 3.12)
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	sed -i "s/'-g0', '-flto'//" setup.py || die
+
+	distutils-r1_src_prepare
+
+	DISTUTILS_ARGS=(
+		--dynamic-link-zstd
+		--multi-phase-init
+	)
+}
+
+python_test() {
+	eunittest tests
+}