From 3f64e11797d30cd54100ffeca585b09b549c328f Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 31 Dec 2022 16:49:58 +0100
Subject: [PATCH] dev-python/pycdio: PEP517, pytest
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/888255
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pycdio/pycdio-2.1.1-r1.ebuild | 55 ++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 dev-python/pycdio/pycdio-2.1.1-r1.ebuild

diff --git a/dev-python/pycdio/pycdio-2.1.1-r1.ebuild b/dev-python/pycdio/pycdio-2.1.1-r1.ebuild
new file mode 100644
index 0000000000000..94f8d9a685c49
--- /dev/null
+++ b/dev-python/pycdio/pycdio-2.1.1-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python OO interface to libcdio (CD Input and Control library)"
+HOMEPAGE="
+	https://savannah.gnu.org/projects/libcdio/
+	https://pypi.org/project/pycdio/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+DEPEND="
+	>=dev-libs/libcdio-2.0.0
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-lang/swig
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Remove obsolete sys.path and adjust 'data' paths in examples.
+	sed -i \
+		-e "s:^sys.path.insert.*::" \
+		-e "s:\.\./data:./data:g" \
+		example/*.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest -opython_files='test-*.py'
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}