dev-python/patsy: Version Bump

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec@gentoo.org>

dev-python/patsy/patsy-0.4.1.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python module to describe statistical models and design matrices"
+HOMEPAGE="http://patsy.readthedocs.org/en/latest/index.html"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		)
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+	nosetests -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( doc/_build/html/. )
+	distutils-r1_python_install_all
+}