From 3eed78efffc7dbcc22d39e006980d2c4424c6d1c Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 19 May 2026 06:59:03 +0200
Subject: [PATCH] dev-python/oslo-config: Bump to 10.4.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/oslo-config/Manifest               |  1 +
 .../oslo-config/oslo-config-10.4.0.ebuild     | 57 +++++++++++++++++++
 2 files changed, 58 insertions(+)
 create mode 100644 dev-python/oslo-config/oslo-config-10.4.0.ebuild

diff --git a/dev-python/oslo-config/Manifest b/dev-python/oslo-config/Manifest
index a8d078de6f8f5..f1ada17116ea4 100644
--- a/dev-python/oslo-config/Manifest
+++ b/dev-python/oslo-config/Manifest
@@ -1 +1,2 @@
 DIST oslo_config-10.3.0.tar.gz 164302 BLAKE2B 973e637cd4e75904a651fda32517a5fd4b42c69fe4f6674ac6163a4eab5588c5188ccbbc923861b0f9b4c587304746df676ab6c5994842da14edec6594eee925 SHA512 c72ecea5670d4e9267096f5499821156fa795d359ce072ce9b730155b10b218768926d5e4104f5a4aa3d2f9a79db2e419d227567e9ff5d83e900efad956097f1
+DIST oslo_config-10.4.0.tar.gz 168943 BLAKE2B 7621204df281296ac5c7d80f99369f37385e12cae1da06799c9158a0b7b17043c82612379864b2c3a007cd986ad3ce2643db4076fbce8658350ea0d8af843ee4 SHA512 a390700c5f824cb0d3c7ba79fd692f61714ddcc2e446ac0cf7648a1939096767b5b26a425b1156ca8d078035696c43119c3d8ff1214c67637cf21f74ac996da4
diff --git a/dev-python/oslo-config/oslo-config-10.4.0.ebuild b/dev-python/oslo-config/oslo-config-10.4.0.ebuild
new file mode 100644
index 0000000000000..69dba48a410f9
--- /dev/null
+++ b/dev-python/oslo-config/oslo-config-10.4.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Oslo Configuration API"
+HOMEPAGE="
+	https://opendev.org/openstack/oslo.config/
+	https://github.com/openstack/oslo.config/
+	https://pypi.org/project/oslo.config/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-1.3[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-5.6.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.5.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.8.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# broken by some dep upgrade
+	sed -i oslo_config/tests/test_cfg.py \
+		-e '/DeprecationWarningTestsNoOsloLog/,$d' \
+		-e 's/test_sub_command_multiple/_&/' || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x COLUMNS=80
+	eunittest -b
+}