dev-python/translate-toolkit: 2.0.0_beta6 bump, python3, EAPI 6, HOMEPAGE

Replaced sphinx-bootstrap-theme with classic theme to make USE=doc work.

Package-Manager: portage-2.3.0
Closes: https://github.com/gentoo/gentoo/pull/2513

Signed-off-by: David Seifert <soap@gentoo.org>

dev-python/translate-toolkit/Manifest

@@ -1 +1,2 @@
 DIST translate-toolkit-1.12.0.tar.bz2 5329772 SHA256 11e332f2a29d8644364b4ca79b4ac079df328626ec8c27ac0e8cc454696719ca SHA512 c84424790ad66492dec97a5ec5601f5ffa68d23b219836def998847449b902970ac32fcb7d06455365e00c7b06f49d7dedda5257275bf7e845b16100153922dd WHIRLPOOL 866eb62056a30c8042d96a1ec06a23e56c2a5121dd66234a8b0889193548fff962d4c56700bb50a01c793e2443d49e33a02d92d5b53513f6c7b0805af827decf
+DIST translate-toolkit-2.0.0_beta6.tar.gz 1096681 SHA256 1abe04be3c886a52bdb90e33dffb7e96d82e7f5ba1fed41f12165a4a4b8def29 SHA512 08b8091b17a96925db09ab42536248c458a895d8a221af8be66bc4737ba233a70341ba9fab7047733ec0ad284b23f3694a361c726a952eb42427b9c01916ad79 WHIRLPOOL 1d9be301036073a1a1c6afb07b2cb77433457e26caf31d0577148b8f076b160d971c08d864e9b2fa947e3e55fbe7ede08af75570cc572422e7dc4c63f55b7863

dev-python/translate-toolkit/metadata.xml

@@ -12,6 +12,6 @@
 		<flag name="subtitles">Support conversion between po and sub files</flag>
 	</use>
 	<upstream>
-		<remote-id type="sourceforge">translate</remote-id>
+		<remote-id type="github">translate</remote-id>
 	</upstream>
 </pkgmetadata>

dev-python/translate-toolkit/translate-toolkit-2.0.0_beta6.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MY_PN="${PN/-toolkit}"
+MY_PV="${PV/_beta/b}"
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate"
+SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc +html +ical +ini +subtitles"
+
+COMMON_DEPEND="
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+"
+DEPEND="${COMMON_DEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+RDEPEND="${COMMON_DEPEND}
+	app-text/iso-codes
+	>=dev-python/chardet-2.3.0[${PYTHON_USEDEP}]
+	dev-python/diff-match-patch[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.5[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( dev-python/iniparse[${PYTHON_USEDEP}] )
+	subtitles? ( $(python_gen_cond_dep 'media-video/gaupol[${PYTHON_USEDEP}]' python3_{4,5}) )
+"
+
+REQUIRED_USE="
+	subtitles? ( || ( $(python_gen_useflags 'python3*') ) )
+"
+
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+python_prepare_all() {
+	# Prevent unwanted d'loading in doc build
+	sed -e "/^    'sphinx.ext.intersphinx',/d" \
+		-e "/html_theme/ s/sphinx-bootstrap/classic/" \
+		-i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${S}"/docs/_build/html/. )
+	distutils-r1_python_install_all
+	rm -Rf docs || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	if ! use html; then
+		rm "${ED}"usr/bin/html2po || die
+		rm "${ED}"usr/bin/po2html || die
+	fi
+	if ! use ical; then
+		rm "${ED}"usr/bin/ical2po || die
+		rm "${ED}"usr/bin/po2ical || die
+	fi
+	if ! use ini; then
+		rm "${ED}"usr/bin/ini2po || die
+		rm "${ED}"usr/bin/po2ini || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"usr/bin/sub2po || die
+		rm "${ED}"usr/bin/po2sub || die
+	fi
+}