dev-python/sphinx: version bump to 1.7.5

Closes: https://bugs.gentoo.org/648712

dev-python/sphinx/Manifest

@@ -5,3 +5,4 @@ DIST Sphinx-1.3.5.tar.gz 3679978 BLAKE2B 2a88859bfd4a3de75a7b56fce65086e1239c3c5
 DIST Sphinx-1.6.3.tar.gz 4674251 BLAKE2B ba13de3d72fbc5cbc3632a1062001ed287798efe5f04064d241b645d6e4c52c9d9c115aaae4ae7b94213bbddf595a93480788d66b3a54eac3c9fb415d007d4ca SHA512 d5aec58e19239db4e61fcd6b103fcc838d97aad5a7aaf9279ff1097791d9cd1ba245989307a2d1049c123058b84ca4e91db192a1672c040d80fafed3907736ae
 DIST Sphinx-1.6.5.tar.gz 4680974 BLAKE2B 97b0cff21985de071d29651824f2954ca4d12c5095fb8049597235c8071bccb00344e89fc4a90ca010fe79a76faf0e5ae2b09ed698f1c5bcfd8f06de64169107 SHA512 c6ba7ba639f9814867d9abaaac48d58daa9d0ea9ceae4495bdbd311856833314eade2d9df7213c0357d5eea53d525c5a1235bc977a07cc7ef82e1ff0ecb51f3d
 DIST Sphinx-1.6.7.tar.gz 4692169 BLAKE2B cde46b6e9dd2c39a592802e57becbb6f61e6d370ed08fdeb41270c8177818f48f68a6e03c174b8d70453ac6f936fa25a4c2bccbf9eb7e84a008027321db93209 SHA512 bc852d4694bf433a8a1d931bc67e4c8bf50789f833be8a338eb934325734b9fbc361c1d203ecd6e28f9c0dff5edb090556372d9403cc55d4972b18bdd4b7bfd4
+DIST Sphinx-1.7.5.tar.gz 4726802 BLAKE2B 8d828dcae1f3ebb813c5f2de8c096a3fac4ab88b424955c27592349c544b775a21703c904a54efa7f86e1967198f4950804904a82a7142a3499f33c5343506e3 SHA512 db2a8df2cdb2ed78ce2341175575c2b04a149451b2bc8a4f74ddc73e308a19d505874fdbae4e370ce48a9b1cdb4de47cdab489bc57c1b378e857d5b8d04a07b8

dev-python/sphinx/sphinx-1.7.5.ebuild

@@ -0,0 +1,96 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="http://www.sphinx-doc.org/"
+SRC_URI="mirror://pypi/S/${PN^}/${P^}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~ppc-macos ~x86-fbsd ~x86-macos ~x86-linux ~x64-macos ~x64-solaris"
+IUSE="doc latex net test"
+
+RDEPEND="
+	>=dev-python/alabaster-0.7.9[${PYTHON_USEDEP}]
+	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.1.1[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.11[${PYTHON_USEDEP}]
+	dev-python/imagesize[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0.1-r1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.5[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-1.1[${PYTHON_USEDEP}]
+	>=dev-python/sphinx_rtd_theme-0.1[${PYTHON_USEDEP}]
+	<dev-python/sphinx_rtd_theme-2.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+	dev-python/typing[${PYTHON_USEDEP}]
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+	net? (
+		>=dev-python/sqlalchemy-0.9[${PYTHON_USEDEP}]
+		>=dev-python/whoosh-2.0[${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/simplejson[${PYTHON_USEDEP}]
+		>=dev-python/sqlalchemy-0.9[${PYTHON_USEDEP}]
+		>=dev-python/whoosh-2.0[${PYTHON_USEDEP}]
+		virtual/imagemagick-tools[jpeg,png,svg]
+		virtual/python-enum34[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${P^}"
+
+python_prepare_all() {
+	# remove tests that fail due to network-sandbox
+	rm tests/test_websupport.py || die "Failed to remove web tests"
+	rm tests/test_build_linkcheck.py || die "Failed to remove web tests"
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	# Generate the grammar. It will be caught by install somehow.
+	# Note that the tests usually do it for us. However, I don't want
+	# to trust USE=test really running all the tests, especially
+	# with FEATURES=test-fail-continue.
+	pushd "${BUILD_DIR}"/lib >/dev/null || die
+	"${EPYTHON}" -m sphinx.pycode.__init__ || die "Grammar generation failed."
+	popd >/dev/null || die
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C doc SPHINXBUILD='"${EPYTHON}" "${S}/sphinx-build.py"' html
+		HTML_DOCS=( doc/_build/html/. )
+	fi
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+	cp -r -l tests "${BUILD_DIR}"/ || die "Failed to copy tests"
+	cp Makefile "${BUILD_DIR}"/ || die "Failed to copy Makefile"
+	emake test
+}