dev-cpp/cli11: add 2.4.2

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

dev-cpp/cli11/Manifest

@@ -1 +1,2 @@
 DIST cli11-2.4.1.tar.gz 339023 BLAKE2B 4db4bacc30ae5526135fe354e4f707f6858cb42b0662daafdde23cf397701c5185794d72794d920ef8f66ce846aafa718ac24fb567b04144d5b15905ed4badd7 SHA512 965290d09977672d3bc3c57ca4b89a88c2c09461da6e866b18217d702d4d5a0977588fcb8fef1a3c3804e61ad80d276029f47469cc83dbfdc7021ee35f6b7269
+DIST cli11-2.4.2.tar.gz 343478 BLAKE2B b1a71bb9495ca86eac62af800919dd78899bd972cfc05035659a3c0a8d07f70ccdc076d18756ba20ddffe31c9dc346e4579474284e601497fcac6c6866e536de SHA512 fdb61c430f5b99a9495fda7f94bfc8d0fb5360c99beeccbcb3b8918713579aac97fa0dcbce296065d9043f141a538c505919c9810fd1d192661e8b48b6a2637a

dev-cpp/cli11/cli11-2.4.2.ebuild

@@ -0,0 +1,55 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Command line parser for C++11"
+HOMEPAGE="https://cliutils.github.io/CLI11/book/"
+SRC_URI="
+	https://github.com/CLIUtils/CLI11/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+S=${WORKDIR}/${PN^^}-${PV}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	test? (
+		dev-cpp/catch:0
+		dev-libs/boost
+	)
+"
+BDEPEND="
+	doc? (
+		app-text/doxygen
+		media-gfx/graphviz
+	)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCLI11_BUILD_DOCS=$(usex doc)
+		-DCLI11_BUILD_EXAMPLES=no
+		-DCLI11_BUILD_TESTS=$(usex test)
+		$(usev test -DCLI11_BOOST=yes)
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile all $(usev doc docs)
+}
+
+src_install() {
+	local DOCS=( CHANGELOG.md README.md book/{chapters,code,*.md} )
+	cmake_src_install
+
+	use doc && dodoc -r "${BUILD_DIR}"/docs/html
+}