mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-06 02:17:34 -08:00
app-office/calligra: add 25.12.0, fixes build w/ eigen-5
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
parent
fa3518c36a
commit
3bb725e3ed
@ -1,2 +1,3 @@
|
||||
DIST calligra-25.08.2.tar.xz 58039844 BLAKE2B 7bde4531c7631ff98ce4245150e881827dcb319d19dc7493d102d9887f6366dcd5121dc03f27f831daf52c667f6b468e0c7f975287b65c1dc41f9f58fa1ce5c1 SHA512 968c582ebe379bce9e80b54c06e33daadaaa30c2237285bbdf8bd656145cde03544f2c0bdbdb6767f9d5aa37c910c5f6af09027d5f8764ae4914c1a8b14d8460
|
||||
DIST calligra-25.12.0.tar.xz 58046252 BLAKE2B 2b83a3ccdb126c04ce627e21ee9b852ba911b52f65fb3bda800420716e43a7bb4fa7d15cbb9d8287fa95e56d6e255e73888e21baaa35602f9b3655f5676eefac SHA512 6e790aee22abae1d492f0ffdaa3181471a55359665a3d50f4b52d540b64e1738b04befd98702645b96efb6a4d787d6f62be597ccc71f8e4fd293ecc2b4bffd3f
|
||||
DIST calligra-3.2.1-patchset-1.tar.xz 11924 BLAKE2B 5a71a7960a6d2a4d5e55129f4812fb13a2fb56613283d4582266e1836f107b711be43cb158e29c440fbda6992c03a3f4907f0600d21522fd9ab07c66354234a9 SHA512 26ec818f2415c43b116b716557710361621e1e4446087fe123e29107f82400ec82f19ab3a76dde9b749ed4b9f15da9c05c3fa6137fc814241c48ffc12f5628fc
|
||||
|
||||
143
app-office/calligra/calligra-25.12.0.ebuild
Normal file
143
app-office/calligra/calligra-25.12.0.ebuild
Normal file
@ -0,0 +1,143 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
CHECKREQS_DISK_BUILD="4G"
|
||||
ECM_HANDBOOK="forceoptional"
|
||||
ECM_TEST="forceoptional"
|
||||
KFMIN=6.19.0
|
||||
QTMIN=6.9.1
|
||||
inherit check-reqs ecm gear.kde.org xdg
|
||||
|
||||
DESCRIPTION="KDE Office Suite"
|
||||
HOMEPAGE="https://calligra.org/"
|
||||
PATCHSET="${PN}-3.2.1-patchset-1"
|
||||
SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${PATCHSET}.tar.xz"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
if [[ ${KDE_BUILD_TYPE} == release ]]; then
|
||||
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
|
||||
fi
|
||||
CAL_FTS=( karbon sheets stage words )
|
||||
IUSE="+charts +fontconfig gsl +import-filter +lcms okular +pdf phonon
|
||||
+truetype webengine X $(printf 'calligra_features_%s ' ${CAL_FTS[@]})"
|
||||
|
||||
RESTRICT="test"
|
||||
|
||||
# TODO: Not packaged: Cauchy (https://bitbucket.org/cyrille/cauchy)
|
||||
# Required for the matlab/octave formula tool
|
||||
COMMON_DEPEND="
|
||||
dev-lang/perl
|
||||
dev-libs/openssl:=
|
||||
>=dev-libs/qtkeychain-0.14.2:=[qt6(+)]
|
||||
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
|
||||
>=dev-qt/qtsvg-${QTMIN}:6
|
||||
>=dev-qt/qttools-${QTMIN}:6[designer]
|
||||
>=kde-frameworks/karchive-${KFMIN}:6
|
||||
>=kde-frameworks/kcmutils-${KFMIN}:6
|
||||
>=kde-frameworks/kcompletion-${KFMIN}:6
|
||||
>=kde-frameworks/kconfig-${KFMIN}:6
|
||||
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kcrash-${KFMIN}:6
|
||||
>=kde-frameworks/kdbusaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kguiaddons-${KFMIN}:6
|
||||
>=kde-frameworks/ki18n-${KFMIN}:6
|
||||
>=kde-frameworks/kiconthemes-${KFMIN}:6
|
||||
>=kde-frameworks/kio-${KFMIN}:6
|
||||
>=kde-frameworks/kirigami-${KFMIN}:6
|
||||
>=kde-frameworks/kitemviews-${KFMIN}:6
|
||||
>=kde-frameworks/kjobwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/knotifications-${KFMIN}:6
|
||||
>=kde-frameworks/knotifyconfig-${KFMIN}:6
|
||||
>=kde-frameworks/ktextwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kwindowsystem-${KFMIN}:6
|
||||
>=kde-frameworks/kxmlgui-${KFMIN}:6
|
||||
>=kde-frameworks/sonnet-${KFMIN}:6
|
||||
virtual/libiconv
|
||||
virtual/zlib:=
|
||||
charts? ( dev-libs/kdiagram:6 )
|
||||
fontconfig? ( media-libs/fontconfig )
|
||||
gsl? ( sci-libs/gsl:= )
|
||||
import-filter? (
|
||||
app-text/libetonyek
|
||||
app-text/libodfgen
|
||||
app-text/libwpd:*
|
||||
app-text/libwpg:*
|
||||
>=app-text/libwps-0.4
|
||||
dev-libs/librevenge
|
||||
media-libs/libvisio
|
||||
)
|
||||
lcms? ( media-libs/lcms:2 )
|
||||
okular? ( kde-apps/okular:6 )
|
||||
pdf? ( app-text/poppler:=[qt6] )
|
||||
phonon? ( >=media-libs/phonon-4.12.0[qt6(+)] )
|
||||
truetype? ( media-libs/freetype:2 )
|
||||
webengine? ( >=dev-qt/qtwebengine-${QTMIN}:6[widgets] )
|
||||
calligra_features_sheets? ( dev-cpp/eigen:3 )
|
||||
calligra_features_words? ( dev-libs/libxslt )
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
dev-libs/boost
|
||||
lcms? ( dev-libs/imath:3 )
|
||||
test? ( >=kde-frameworks/threadweaver-${KFMIN}:6 )
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
!${CATEGORY}/${PN}:5
|
||||
calligra_features_karbon? ( media-gfx/pstoedit[plotutils] )
|
||||
"
|
||||
BDEPEND="
|
||||
sys-devel/gettext
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
"${WORKDIR}"/${PATCHSET}/${PN}-3.1.89-no-arch-detection.patch # downstream
|
||||
"${FILESDIR}"/${PN}-25.08.2-cmake4.patch # pending MR
|
||||
)
|
||||
|
||||
src_configure() {
|
||||
local cal_ft myproducts
|
||||
|
||||
# applications
|
||||
for cal_ft in ${CAL_FTS[@]}; do
|
||||
use calligra_features_${cal_ft} && myproducts+=( "${cal_ft^^}" )
|
||||
done
|
||||
|
||||
use lcms && myproducts+=( PLUGIN_COLORENGINES )
|
||||
use okular && myproducts+=( OKULAR )
|
||||
|
||||
local mycmakeargs=(
|
||||
-DPACKAGERS_BUILD=OFF
|
||||
-DRELEASE_BUILD=ON
|
||||
-DWITH_Iconv=ON
|
||||
-DWITH_Imath=ON # w/ LCMS: 16 bit floating point Grayscale colorspace
|
||||
-DCMAKE_DISABLE_FIND_PACKAGE_Cauchy=ON
|
||||
-DPRODUCTSET="${myproducts[*]}"
|
||||
$(cmake_use_find_package charts KChart6)
|
||||
-DWITH_Fontconfig=$(usex fontconfig)
|
||||
-DWITH_GSL=$(usex gsl)
|
||||
-DWITH_LibEtonyek=$(usex import-filter)
|
||||
-DWITH_LibOdfGen=$(usex import-filter)
|
||||
-DWITH_LibRevenge=$(usex import-filter)
|
||||
-DWITH_LibVisio=$(usex import-filter)
|
||||
-DWITH_LibWpd=$(usex import-filter)
|
||||
-DWITH_LibWpg=$(usex import-filter)
|
||||
-DWITH_LibWps=$(usex import-filter)
|
||||
$(cmake_use_find_package phonon Phonon4Qt6)
|
||||
-DWITH_LCMS2=$(usex lcms)
|
||||
-DWITH_Okular6=$(usex okular)
|
||||
-DWITH_Poppler=$(usex pdf)
|
||||
-DWITH_PopplerXPDFHeaders=$(usex pdf)
|
||||
-DWITH_Eigen3=$(usex calligra_features_sheets)
|
||||
-DBUILD_UNMAINTAINED=$(usex calligra_features_stage)
|
||||
-DWITH_Freetype=$(usex truetype)
|
||||
$(cmake_use_find_package webengine Qt6WebEngineWidgets)
|
||||
)
|
||||
|
||||
ecm_src_configure
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user