dev-python/pyopenssl: 19.0.0 version bump

Closes: https://bugs.gentoo.org/678452
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Craig Andrews <candrews@gentoo.org>

dev-python/pyopenssl/Manifest

@@ -1,2 +1,3 @@
 DIST pyOpenSSL-17.5.0.tar.gz 170870 BLAKE2B e8b8986a7c5475ac3898df4877a8be86db359af79e1718bad85149440cff543c501ee23eb369270d2c539a9e3f4e13165ea87b858ef6916ee79ca6e49f6e5370 SHA512 f194662b5842f1e3a4fcb910b9f2e6482d1dcdf834f306acc3dd6d9723f65038f7bff550248fa6268d90c839c9d9e8248bb6c7d399495fe6aed25291b93ece86
 DIST pyOpenSSL-18.0.0.tar.gz 167296 BLAKE2B 3a9c8db02e92858353389508d9791d2ff0b07b54150d27a513b4c26ef62899167d184702cd8ac3a9fb5be120a92e31259ce265a400513de4622c30b1269ecd9f SHA512 7106d4116243a164c1f458ad495564c2cf3a46b4b0fbb1d452b4174ead4409bc9c783c3a4674231ed3c26ecf588077b01dadbdefe033d5e7251a61531c6f6c15
+DIST pyOpenSSL-19.0.0.tar.gz 168551 BLAKE2B 762d3358b3cc4f1e088e9464ac079e5212c537d25691e51edb3255a192c42276506c758ecf16eff999082bfd05aeb92a37741338d92036d2149b87c95008db05 SHA512 a7e12bf5be725ccebd1223d567a9b9e8bd35f79cbf3a0409108fa6f00e10ab137dd6876369e9dede02b2abc7d700786cc905532ca5c31b6e246f6df8b24e2818

dev-python/pyopenssl/pyopenssl-19.0.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} pypy{,3} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN=pyOpenSSL
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python interface to the OpenSSL library"
+HOMEPAGE="
+	http://pyopenssl.sourceforge.net/
+	https://launchpad.net/pyopenssl
+	https://pypi.org/project/pyOpenSSL/
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-python/six-1.5.2[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.3[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		virtual/python-cffi[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		>=dev-python/pytest-3.0.1[${PYTHON_USEDEP}]
+	)"
+
+S=${WORKDIR}/${MY_P}
+
+python_prepare_all() {
+	# Requires network access
+	sed -i -e 's/test_set_default_verify_paths/_&/' tests/test_ssl.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	TZ=UTC py.test -v || die "Testing failed with ${EPYTHON}" # Fixes bug #627530
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	if use examples ; then
+		docinto examples
+		dodoc -r examples/*
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}