From 39acd6962fa46543f6b77d044c726a49f33846e3 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 7 Feb 2026 08:13:07 +0100
Subject: [PATCH] dev-python/authlib: Bump to 1.6.7
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/authlib/Manifest             |  1 +
 dev-python/authlib/authlib-1.6.7.ebuild | 74 +++++++++++++++++++++++++
 2 files changed, 75 insertions(+)
 create mode 100644 dev-python/authlib/authlib-1.6.7.ebuild

diff --git a/dev-python/authlib/Manifest b/dev-python/authlib/Manifest
index 49c86a734ead3..61bc8b54a246d 100644
--- a/dev-python/authlib/Manifest
+++ b/dev-python/authlib/Manifest
@@ -1 +1,2 @@
 DIST authlib-1.6.6.gh.tar.gz 329249 BLAKE2B cab561d2a9faf2eba0392ebbf4a6ca7c79474591eba4d2e02548c7893f8988af9c9e8e366f6cb02051a64953c7e4425493231e0738e8953d003d5d122b1dd407 SHA512 5b9f6043503d3d709620fd853a0f5405f213bbff2b2d037676a64b6f10b1e067bf7fa8b0bb7534a7c8bd2edcf80b1277903b0d7532cb1d3a17de56400236ea58
+DIST authlib-1.6.7.gh.tar.gz 329587 BLAKE2B 60ad24eebf39532c46eef23ad4ee57948d8ad4b2eb52fe9df53235bfd87a4ac64f9ebae9d482c873034ee7474630d4c7e5b17f2b7eb3edd41bce2aaf5f0dd593 SHA512 2de10426fc12fb7a7ab9d286e1aef3762511543df4da2454ecf350ab3d0aa8b05f0403297ce7e74fa769c21236a91188696ba1b89b80ecf56435f629c47255b9
diff --git a/dev-python/authlib/authlib-1.6.7.ebuild b/dev-python/authlib/authlib-1.6.7.ebuild
new file mode 100644
index 0000000000000..319478d1c4712
--- /dev/null
+++ b/dev-python/authlib/authlib-1.6.7.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="setuptools"
+PYTHON_COMPAT=( python3_{12..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python library in building OAuth and OpenID Connect servers and clients"
+HOMEPAGE="
+	https://authlib.org/
+	https://github.com/authlib/authlib/
+	https://pypi.org/project/Authlib/
+"
+# pypi source distribution excludes the tests
+SRC_URI="
+	https://github.com/authlib/authlib/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="django flask jose test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	django? (
+		dev-python/django[${PYTHON_USEDEP}]
+	)
+	flask? (
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+	)
+	jose? (
+		>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/anyio[${PYTHON_USEDEP}]
+		dev-python/cachelib[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/starlette[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-asyncio )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# convert from pycryptodomex to pycryptodome
+	sed -i -e 's:from Cryptodome:from Crypto:' \
+		authlib/jose/drafts/_jwe_enc_cryptodome.py || die
+}
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.django_settings
+	epytest tests/{core,jose,clients,flask}
+
+	# TODO: django.core.exceptions.AppRegistryNotReady: Apps aren't loaded yet.
+	#epytest tests/django
+}