dev-java/openjdk-jre-bin: add 11.0.12_p7

Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

dev-java/openjdk-jre-bin/Manifest

@@ -1,3 +1,4 @@
 DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.11_9.tar.gz 42432277 BLAKE2B 18138eb163db4609790286cfe7bc951da9ea244eed50bafa10e5d84ec43e7a80ebc2f759f3e1547b9d785b1a6d560b5399a0449a8fe301e19625c2b98abba928 SHA512 5b8c1c16c5faa467bbb35a1d1e694afc50b0c2dbbe77abb29620f30602187a1a903f60169e2b691dcc81b6d902ed5a17239318f27765f19351281209befb0e96
+DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.12_7.tar.gz 42400222 BLAKE2B 4cb727bac0a68f2b7461569d96fb4b5b6f9d0d915edf1e869cc72ed9a0bcd977f365923f1b23031e15cba4ac46d336f011bcd5f2230454b436e839cc5e1371b8 SHA512 662a65f2d601b537f3b05d06cb1785d341d519c24cd86f2a4ef8886919d7793be363da1bb8833cb81c6bc4f2e1456cc0f34e5831c6ac80924a93002c2f156691
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u292b10.tar.gz 41355668 BLAKE2B 761358d7e5dd9c96ed13d7302ea5f39719f044a37add7fcadb76ed799d41b17faee014c9e4bec3ce388d4a6965e2c14dd4ddf029baa6dd1f5f84cde7e7b1fcd5 SHA512 fd63dceddcd32b0f48b6d35c14ab3165f2b45152fdbc2bcaf833ed2624d833592cf1001627029fd04f9b77a033e2d4e993830d54c2e7c08adde5cd7a684447fd
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u302b08.tar.gz 41249161 BLAKE2B 643c8cdb50e6d7ff24bdda2fb8e99d0ee33dcf550313db879bcc4661d85b715de4e6e01b979e92005208b004ad1d6e0641e328dfacb81f70541a759f022826a8 SHA512 e435cf0d9e5a8edb26ada1568a6a041b685bd92302ddc60be73acc02aa1aaa43fda08d327d456749405866a0d1e3feaded2796d8a0db65fa650a9e60520bcb96

dev-java/openjdk-jre-bin/openjdk-jre-bin-11.0.12_p7.ebuild

@@ -0,0 +1,97 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/adoptium/temurin${SLOT}-binaries/releases/download/jdk-${MY_PV}/OpenJDK${SLOT}U-jre_${1}_linux_hotspot_${MY_PV//+/_}.tar.gz
+		)"
+}
+
+MY_PV=${PV/_p/+}
+SLOT=${MY_PV%%[.+]*}
+
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by Eclipse Temurin"
+HOMEPAGE="https://adoptium.net"
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+IUSE="alsa cups +gentoo-vm headless-awt selinux"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk-${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED%/}/${dest#/}"
+
+	# Not sure why they bundle this as it's commonly available and they
+	# only do so on x86_64. It's needed by libfontmanager.so. IcedTea
+	# also has an explicit dependency while Oracle seemingly dlopens it.
+	rm -vf lib/libfreetype.so || die
+
+	# Oracle and IcedTea have libjsoundalsa.so depending on
+	# libasound.so.2 but AdoptOpenJDK only has libjsound.so. Weird.
+	if ! use alsa ; then
+		rm -v lib/libjsound.* || die
+	fi
+
+	if use headless-awt ; then
+		rm -v lib/lib*{[jx]awt,splashscreen}* || die
+	fi
+
+	rm -v lib/security/cacerts || die
+	dosym ../../../../etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	# provide stable symlink
+	dosym "${P}" "/opt/${PN}-${SLOT}"
+
+	use gentoo-vm && java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+	java-vm-2_pkg_postinst
+
+	if use gentoo-vm ; then
+		ewarn "WARNING! You have enabled the gentoo-vm USE flag, making this JRE"
+		ewarn "recognised by the system. This will almost certainly break things."
+	else
+		ewarn "The experimental gentoo-vm USE flag has not been enabled so this JRE"
+		ewarn "will not be recognised by the system. For example, simply calling"
+		ewarn "\"java\" will launch a different JVM. This is necessary until Gentoo"
+		ewarn "fully supports Java 11. This JRE must therefore be invoked using its"
+		ewarn "absolute location under ${EPREFIX}/opt/${P}."
+	fi
+}