dev-python/packaging: version bump to 17.1

dev-python/packaging/Manifest

@@ -1 +1,2 @@
 DIST packaging-16.8.tar.gz 44706 BLAKE2B 6443f05d3745eb6c4cc3d51fccfb1afcfa207ac12498be4d15cd0f5c52c80435f8ea513589e8aec671cf88b10cc8c98555e7cac7fe9a1e0c67f4625fce83f80f SHA512 d1a7b65472c7c02dd758f0c469d6c6aeea34de7b798613f7fcdf45fcccbeba1e9085cab113fa89b392a60f758f8747d13b1c265c809566990c22e61ca8db49bb
+DIST packaging-17.1.tar.gz 49849 BLAKE2B ceea74025c55c832cdd36b8464bb15862d8ee60387de973d7453d5cb8ec0b430d1e49a1b13c9dccb8b9c4c898cb07829f6fd04ca700d8cb2c5ba2b7abc0d160e SHA512 52d2f482ae5cd0f8e7b3ac35c4b270ca736bc4f7ebaa569631d1dcb8ea024ee6f75127ca2aa3c95e686ebbd427de2ef4bc01bcd839591f7b4c1e26f9b8d9acb0

dev-python/packaging/packaging-17.1.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy pypy3  )
+
+inherit distutils-r1
+
+DESCRIPTION="Core utilities for Python packages"
+HOMEPAGE="https://github.com/pypa/packaging https://pypi.org/project/packaging/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="|| ( Apache-2.0 BSD-2 )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/pyparsing-2.1.10[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-16.8-distutils.patch"
+)
+
+python_test() {
+	py.test --capture=no --strict -v || die
+}
+
+pkg_preinst() {
+	# https://bugs.gentoo.org/585146
+	cd "${HOME}" || die
+
+	_cleanup() {
+		local pyver=$("${PYTHON}" -c "from distutils.sysconfig import get_python_version; print(get_python_version())")
+		local egginfo="${ROOT%/}$(python_get_sitedir)/${P}-py${pyver}.egg-info"
+		if [[ -d ${egginfo} ]]; then
+			echo rm -r "${egginfo}"
+			rm -r "${egginfo}" || die "Failed to remove egg-info directory"
+		fi
+	}
+	python_foreach_impl _cleanup
+}