app-emacs/org-mode: bump to 9.7.35

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-emacs/org-mode/Manifest

@@ -1 +1,2 @@
 DIST org-mode-release_9.7.34.tar.gz 2365680 BLAKE2B 308389056148e7ae3dba51cc3e754484bc5ec925e2761f6fee7a48a2c11ba8bb2c1bffebbfef6e06f7eaee240a3fd07e39abeb6c2267824f3b1199b283650b2e SHA512 27b80ac4c8c73f9409ccac816322fcabe67fc74ff16ba4fb109bbbcc40dc2bbc32599268f31d124a47741f0113c41cd52d85938f1b08b89fb44807690191ee58
+DIST org-mode-release_9.7.35.tar.gz 2366581 BLAKE2B 55b52b94dde1efe7be7354c3c8ae2aa3a51e2e65a9ae96d255017704bd875cbc4ffc3102ea56f5a90994538b6ec76cc61de406406f03096724ab2a066cc54751 SHA512 93354dc2aa8f3c72b4af599650d0cacb4a1112cdf2a7c72efad70f7ae07d7fbcc5c05cf0770b5f9d110b2118a00c532c08b9eb9ca23acbf64882a8b01283150b

app-emacs/org-mode/org-mode-9.7.35.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp readme.gentoo-r1
+
+DESCRIPTION="An Emacs mode for notes and project planning"
+HOMEPAGE="https://orgmode.org/"
+
+if [[ "${PV}" == 9999 ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/emacs/${PN}"
+	EGIT_CHECKOUT_DIR="${WORKDIR}/org"
+	S="${WORKDIR}/org"
+else
+	MY_P="${PN}-release_${PV}"
+
+	SRC_URI="https://git.savannah.gnu.org/cgit/emacs/${PN}.git/snapshot/${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~riscv ~x86"
+fi
+
+LICENSE="GPL-3+ FDL-1.3+ CC-BY-SA-3.0 odt-schema? ( OASIS-Open )"
+SLOT="0"
+IUSE="doc odt-schema"
+
+BDEPEND="
+	doc? (
+		virtual/texi2dvi
+	)
+"
+
+DOCS=( README.org CONTRIBUTE.org etc/ORG-NEWS )
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	elisp_src_prepare
+
+	# Remove failing tests.
+	rm ./testing/lisp/test-{ob,ob-exp,ob-tangle,ob-shell,org,org-clock}.el \
+		|| die "failed to remove some test files"
+
+	EMAKEARGS=(
+		ORGVERSION="${PV}"
+		ETCDIRS="styles csl $(use odt-schema && echo schema)"
+		lispdir="${EPREFIX}${SITELISP}/${PN}"
+		datadir="${EPREFIX}${SITEETC}/${PN}"
+		infodir="${EPREFIX}/usr/share/info"
+	)
+}
+
+src_compile() {
+	emake -j1 "${EMAKEARGS[@]}"
+
+	if use doc ; then
+		emake -j1 pdf
+		emake -j1 card
+	fi
+}
+
+src_test() {
+	local -x LANG="C"
+
+	emake -j1 "${EMAKEARGS[@]}" TEST_NO_AUTOCLEAN="TRUE" test-dirty
+}
+
+src_install() {
+	if use doc ; then
+		DOCS+=( doc/org.pdf doc/orgcard.pdf doc/orgguide.pdf )
+	fi
+
+	emake -j1 "${EMAKEARGS[@]}" DESTDIR="${D}" install
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	einstalldocs
+
+	local DOC_CONTENTS="Org mode has a large variety of run-time dependencies,
+		so you may have to install one or more additional packages.
+		A non-exhaustive list of these dependencies may be found at
+		<http://orgmode.org/worg/org-dependencies.html>."
+	readme.gentoo_create_doc
+}