diff --git a/media-libs/libdvdread/Manifest b/media-libs/libdvdread/Manifest
index f66849b4bffde..4b23d3baa7f79 100644
--- a/media-libs/libdvdread/Manifest
+++ b/media-libs/libdvdread/Manifest
@@ -1 +1,2 @@
 DIST libdvdread-6.1.3.tar.bz2 395439 BLAKE2B 7a8c0b69692059d51a9d94fc4c934f8259c2aa71ac9a9e6d5da22b3668fcbdf000c47fbc7fdb1257f65b90b4d8a4733e01fc2936033246cf2c6a5b68fef81647 SHA512 c98055829ccbbe2bb7b5df48f6e279cf6e91ecab39a35c37081581452f7df7531c1d7b8abd641c55eeee357235b2658b31478dbc307995cffdf8c011bd0dd0bc
+DIST libdvdread-7.0.1.tar.xz 90460 BLAKE2B 1c4588d8ceeef1c603a2b17a346237763b6a2d25dad738b985e4f66f4a76f564f68431abc77f644678bdf315f67b1c0cf127b7b46d35bd4f11a7711aed7236ff SHA512 03e7376327ba211fcc51ee4e4705b1cc7649c613a96e186eb62821b57a11a519c46720e33cf3351cd95fa02db200e40d3b1b9f7e4fe5a3003853fc40c5f511f0
diff --git a/media-libs/libdvdread/libdvdread-7.0.1.ebuild b/media-libs/libdvdread/libdvdread-7.0.1.ebuild
new file mode 100644
index 0000000000000..ef4180c931086
--- /dev/null
+++ b/media-libs/libdvdread/libdvdread-7.0.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib
+
+DESCRIPTION="Library for DVD navigation tools"
+HOMEPAGE="https://www.videolan.org/developers/libdvdnav.html"
+if [[ ${PV} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://code.videolan.org/videolan/libdvdread.git"
+else
+	SRC_URI="https://downloads.videolan.org/pub/videolan/libdvdread/${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+fi
+
+# See https://code.videolan.org/videolan/libdvdread/-/commit/0e020921726ee812e633959d9ad6315ff58b902b
+LICENSE="GPL-2 GPL-3"
+SLOT="0/8" # libdvdread.so.VERSION
+IUSE="+css static-libs"
+
+RDEPEND="css? ( >=media-libs/libdvdcss-1.3.0[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	sed -i -e "s/'COPYING', //" -e "s/doc\/${PN}/doc\/${P}/" meson.build || die
+
+	default
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddefault_library=$(usex static-libs both shared)
+
+		$(meson_feature css libdvdcss)
+	)
+
+	meson_src_configure
+}
diff --git a/media-libs/libdvdread/libdvdread-9999.ebuild b/media-libs/libdvdread/libdvdread-9999.ebuild
index 2016d19c8d1ae..ef4180c931086 100644
--- a/media-libs/libdvdread/libdvdread-9999.ebuild
+++ b/media-libs/libdvdread/libdvdread-9999.ebuild
@@ -1,18 +1,18 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-inherit multilib-minimal
+inherit meson-multilib
 
 DESCRIPTION="Library for DVD navigation tools"
 HOMEPAGE="https://www.videolan.org/developers/libdvdnav.html"
 if [[ ${PV} = 9999 ]]; then
-	inherit autotools git-r3
+	inherit git-r3
 	EGIT_REPO_URI="https://code.videolan.org/videolan/libdvdread.git"
 else
-	SRC_URI="https://downloads.videolan.org/pub/videolan/libdvdread/${PV}/${P}.tar.bz2"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+	SRC_URI="https://downloads.videolan.org/pub/videolan/libdvdread/${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
 fi
 
 # See https://code.videolan.org/videolan/libdvdread/-/commit/0e020921726ee812e633959d9ad6315ff58b902b
@@ -24,27 +24,18 @@ RDEPEND="css? ( >=media-libs/libdvdcss-1.3.0[${MULTILIB_USEDEP}] )"
 DEPEND="${RDEPEND}"
 BDEPEND="virtual/pkgconfig"
 
-DOCS=( AUTHORS ChangeLog NEWS TODO README )
-
 src_prepare() {
-	default
+	sed -i -e "s/'COPYING', //" -e "s/doc\/${PN}/doc\/${P}/" meson.build || die
 
-	if [[ ${PV} == 9999 ]] ; then
-		eautoreconf
-	fi
+	default
 }
 
 multilib_src_configure() {
-	local myeconfargs=(
-		--enable-shared
-		--disable-apidoc
-		$(use_enable static-libs static)
-		$(use_with css libdvdcss)
+	local emesonargs=(
+		-Ddefault_library=$(usex static-libs both shared)
+
+		$(meson_feature css libdvdcss)
 	)
 
-	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
-}
-
-multilib_src_install_all() {
-	find "${ED}" -type f -name "*.la" -delete || die
+	meson_src_configure
 }