kde-apps/kig: 25.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/kig/Manifest

@@ -1 +1,2 @@
 DIST kig-25.08.0.tar.xz 3259640 BLAKE2B 7ecceb979dc9e1b8963c4e45629fcff3922164bf50ace42958c068fef4288279783f53df342f8c5df34c2fb95cdf6008866f7fe0dd44ae82cd145b8169943cac SHA512 669fa11aacb9fb5adf5a9bb78cbbe6cab2a8b7ca8ffccb9cd182cb1b5c36b3f918b5e7d4606dc9c61f391fb75f397903caf73eeccf5718239a3a7a7cf9c44425
+DIST kig-25.08.1.tar.xz 3260744 BLAKE2B 7520bc9e03acc3492da5f24a05c862d8b5c57eff4b3d131bc0138a2e57302663b8a799743037e1f1fe66c7994c722665bda310b84481d4a075a8b85eb48efc7d SHA512 fb87cb98c41ccedf3de7ef9d7226ece765918e6569a8b41298e3db72f0c975a85bc834d1b05d5c29021a1b80acab89baa5b45d1a5bcc978c571a7c8bfbbcd54e

kde-apps/kig/kig-25.08.1.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+PYTHON_COMPAT=( python3_{11..13} )
+KFMIN=6.16.0
+QTMIN=6.9.1
+inherit python-single-r1 ecm gear.kde.org xdg
+
+DESCRIPTION="KDE Interactive Geometry tool"
+HOMEPAGE="https://apps.kde.org/kig/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="scripting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets,xml]
+	>=dev-qt/qtsvg-${QTMIN}:6
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	scripting? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.70:=[python,${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/ktexteditor-${KFMIN}:6
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-25.08.0-cmake-boostpython.patch )
+
+src_prepare() {
+	ecm_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBOOSTPYTHON_VERSION_MAJOR_MINOR=${EPYTHON}
+		$(cmake_use_find_package scripting Boost)
+	)
+
+	ecm_src_configure
+}