diff --git a/dev-libs/libxmlb/Manifest b/dev-libs/libxmlb/Manifest
index 50765b9325849..baff0fbeeaccd 100644
--- a/dev-libs/libxmlb/Manifest
+++ b/dev-libs/libxmlb/Manifest
@@ -1 +1,2 @@
 DIST libxmlb-0.3.21.tar.gz 132251 BLAKE2B 07140d840b7b807cff0c555c18ab33d9bd087d4af4e0bb47088b264a7d9dfff8929ab2820341ec99882c7239d77ee135b2c3592f465667c3bd62aa59396cf0f1 SHA512 5583e547e2e9077552902b5da87a83bfe4a9c723dbd0350b33014b34936feb4fa15fc4b4fedf23ce2aa2c870df57facc376b8549f7d03714df70fe5e738f61c8
+DIST libxmlb-0.3.24.tar.gz 133120 BLAKE2B 59e1c5b9a90c5eef5263dccb54c6513dbd35a404f4e045c5602862eda453eafeca7b1b8cb19924728c2bd4b8f6081eb997f460a2b462c5afb4e72c031ae7a439 SHA512 534e5fe01727b9427137c51984c9ddced91b842c712d4f34f582193c838429b396be6e444246b324d39f6732fdf582a7d89570049f4f48d4a161aff82e33aa49
diff --git a/dev-libs/libxmlb/libxmlb-0.3.24.ebuild b/dev-libs/libxmlb/libxmlb-0.3.24.ebuild
new file mode 100644
index 0000000000000..6d29796cabda1
--- /dev/null
+++ b/dev-libs/libxmlb/libxmlb-0.3.24.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="Library to help create and query binary XML blobs"
+HOMEPAGE="https://github.com/hughsie/libxmlb"
+SRC_URI="https://github.com/hughsie/libxmlb/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/2" # libxmlb.so version
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc introspection +lzma stemmer test +zstd"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	lzma? ( app-arch/xz-utils )
+	stemmer? ( dev-libs/snowball-stemmer:= )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="
+	${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	introspection? (
+		$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	)
+"
+DOCS=( NEWS README.md )
+
+python_check_deps() {
+	if use introspection ; then
+		python_has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+	else
+		return 0
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature lzma)
+		$(meson_feature zstd)
+		$(meson_use doc gtkdoc)
+		$(meson_use introspection)
+		$(meson_use stemmer)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use test; then
+		# Preventing tests from being installed in the first place is a moving target,
+		# just axe them all afterwards.
+		rm -r "${ED}"/usr/{libexec,share}/installed-tests || die
+	fi
+}