dev-python/kombu: 4.1.0 bup

Package-Manager: Portage-2.3.6, Repoman-2.3.3

dev-python/kombu/Manifest

@@ -1,2 +1,3 @@
 DIST kombu-3.0.37.tar.gz 411790 SHA256 e064a00c66b4d1058cd2b0523fb8d98c82c18450244177b6c0f7913016642650 SHA512 ba9bb00e23ce2d3da87eb07aacff8d63ef9879e6ca9f3fe82653cc2ee91610199fe8fc778d7c2e00df05b46130ecda0bdeceda48192b8af1fb0eca41fbb44712 WHIRLPOOL 1e3344eb25024e94d341a3928bd04a9fd13bb41fefd7254e5f2dd70a8b235ae48b93d9b003b21d9ccde4ebdb8d1f349d9af6d54b51c74d6c6b1ee7913ee06919
 DIST kombu-4.0.2.tar.gz 418051 SHA256 d0fc6f2a36610a308f838db4b832dad79a681b516ac1d1a1f9d42edb58cc11a2 SHA512 99be6aa833eedc02897da90ebbd838bf0ac2a21db91350e235fae99ce31607cbc749f73f99d24f76acfc68b81d6263688d35b72ed62bb21d024a3ab385fa666e WHIRLPOOL e140f700c2e00ab892b54664d61c56343fb4d51f65fc0c42e2b4e0b0f75836889f5746061db1f31d3ba5f5981946d47d29ba64b8e6f0561fec054b77167d090e
+DIST kombu-4.1.0.tar.gz 421875 SHA256 4249d9dd9dbf1fcec471d1c2def20653c9310dd1a217272d77e4844f9d5273cb SHA512 fc104a3f974fabf090cc257b1a7623af6048f4630c6c2a9bb693fe69d77b6cdab36135a290a41056c1f854f61cce8fc2aa6b7880e9273581bfdfa162b5724861 WHIRLPOOL 88b59ce41218e7a585b6d9b8240130d7a88c19df85f8cd74acb0263252dd16d4d631f8af546b45555e8aeec4f048a808d55e1e3fb8e9895d0e46cf0cd20a5d68

dev-python/kombu/kombu-4.1.0.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="https://pypi.python.org/pypi/kombu https://github.com/celery/kombu"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples msgpack sqs test"
+
+# couchdb backend support possible via dev-python/couchdb-python
+# ditto dev-python/kazoo(>=1.3.1)
+RDEPEND="
+	>=dev-python/py-amqp-2.1.4[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-3.0[${PYTHON_USEDEP}]
+	dev-python/pyro:4[${PYTHON_USEDEP}]
+	sqs? ( >=dev-python/boto3-1.4.4[${PYTHON_USEDEP}] )
+	msgpack? ( >=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}] )"
+# Fix to https://github.com/celery/kombu/issues/474 obliges dev-python/pymongo to >=-3.0.2
+DEPEND="${RDEPEND}
+	>=dev-python/setuptools-20.6.7[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/case-1.5.2[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/redis-py-2.10.3[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-3.0.2[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}] )
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/couchdb-python[${PYTHON_USEDEP}]
+		>=dev-python/sphinx_celery-1.1[${PYTHON_USEDEP}] )"
+
+# kazoo is optional for tests.
+# Refrain for now, no established demand for it from users
+
+# Req'd for test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+
+PATCHES=(
+	"${FILESDIR}"/${P}-dict-iter.patch
+	)
+
+python_prepare_all() {
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	rm t/unit/transport/test_etcd.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# Doc build misses and skips only content re librabbitmq which is not in portage
+	if use doc; then
+		emake -C docs html || die "kombu docs failed installation"
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}