net-p2p/ktorrent: 25.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

net-p2p/ktorrent/Manifest

@@ -1 +1,2 @@
 DIST ktorrent-25.08.3.tar.xz 2237128 BLAKE2B 2f3c05c0d280e59dc760e8aeb437ec5f96a81802d543aa0f287c29d9fb17c3d6f0f30beeb8ad1e279171c9f3fb0a8e1dbf6fb28dac563cff4f3ec237dbe9bee8 SHA512 385ee1f877e27cf860738d5eaf7857cd53e0f73793362f3f3eded67af422870bd6095779b707ad142088e34a78bb92282c4dac395f0b85f89b31a42d14a0c38e
+DIST ktorrent-25.12.0.tar.xz 2237036 BLAKE2B cf1bf1f2557c634d613c985630336ec1bd86add02eb7b43bbcd67fb94128730b45b614890611a883ec4c048865a7c041feffb19ecb2902cbd6a3ef980321cdbf SHA512 7293a2be67af0cf6b94aef380ff9f100e05c0092a64c1eb0a185fc3ba1cdc02b9833e443dc9426b22313bc187ce84725bd53a48ff86853859003a225c1e6a563

net-p2p/ktorrent/ktorrent-25.12.0.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KFMIN=6.19.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.9.1
+inherit ecm gear.kde.org xdg
+
+DESCRIPTION="Powerful BitTorrent client based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/ktorrent/"
+
+LICENSE="GPL-2"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+bwscheduler +downloadorder +infowidget +ipfilter +logviewer +magnetgenerator
+phonon rss +scanfolder +shutdown +stats +upnp +webengine +zeroconf"
+
+COMMON_DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/knotifyconfig-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=net-libs/libktorrent-${PVCUT}:6
+	infowidget? ( dev-libs/geoip )
+	ipfilter? ( >=kde-frameworks/karchive-${KFMIN}:6 )
+	phonon? (
+		>=media-libs/phonon-4.12.0[qt6(+)]
+		>=media-libs/taglib-1.5:=
+	)
+	rss? (
+		>=dev-qt/qtwebengine-${QTMIN}:6
+		>=kde-frameworks/syndication-${KFMIN}:6
+	)
+	stats? ( >=kde-frameworks/kplotting-${KFMIN}:6 )
+	upnp? ( >=kde-frameworks/kcompletion-${KFMIN}:6 )
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:6 )
+	zeroconf? ( >=kde-frameworks/kdnssd-${KFMIN}:6 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.71
+"
+RDEPEND="${COMMON_DEPEND}
+	ipfilter? (
+		app-arch/bzip2
+		app-arch/unzip
+		kde-apps/kio-extras:6
+		>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	)
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_BWSCHEDULER_PLUGIN=$(usex bwscheduler)
+		-DENABLE_DOWNLOADORDER_PLUGIN=$(usex downloadorder)
+		-DENABLE_INFOWIDGET_PLUGIN=$(usex infowidget)
+		-DENABLE_IPFILTER_PLUGIN=$(usex ipfilter)
+		-DENABLE_LOGVIEWER_PLUGIN=$(usex logviewer)
+		-DENABLE_MAGNETGENERATOR_PLUGIN=$(usex magnetgenerator)
+		$(cmake_use_find_package phonon Taglib)
+		$(cmake_use_find_package phonon Phonon4Qt6)
+		$(cmake_use_find_package rss KF6Syndication)
+		-DENABLE_SCANFOLDER_PLUGIN=$(usex scanfolder)
+		-DENABLE_SHUTDOWN_PLUGIN=$(usex shutdown)
+		-DENABLE_STATS_PLUGIN=$(usex stats)
+		-DENABLE_UPNP_PLUGIN=$(usex upnp)
+		-DENABLE_SEARCH_PLUGIN=$(usex webengine)
+		-DENABLE_ZEROCONF_PLUGIN=$(usex zeroconf)
+	)
+# add back when ported
+#		-DENABLE_WEBINTERFACE_PLUGIN=$(usex webinterface)
+	ecm_src_configure
+}