diff --git a/dev-ruby/builder/builder-3.2.4-r1.ebuild b/dev-ruby/builder/builder-3.2.4-r1.ebuild
new file mode 100644
index 0000000000000..4c68ce67a7859
--- /dev/null
+++ b/dev-ruby/builder/builder-3.2.4-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30 ruby31"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="README.md CHANGES"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A builder to facilitate programatic generation of XML markup"
+HOMEPAGE="http://onestepback.org/"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+all_ruby_prepare() {
+	sed -i \
+		-e '/rdoc\.template .*jamis/d' \
+		Rakefile || die
+
+	rm rakelib/* || die
+}
+
+each_ruby_prepare() {
+	case ${RUBY} in
+		*ruby30|*ruby31)
+			sed -i -e '/test_late_included_module_in_kernel_is_ok/askip "broken due to different ruby behavior"' test/test_blankslate.rb || die
+			;;
+	esac
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:.:test -e 'Dir["test/test_*.rb"].each{|f| require f}' || die
+}