dev-python/python-xlib: version bump to 0.17.

- Project has moved to GitHub: https://github.com/python-xlib/python-xlib
- Support for Python 3 (3.3, 3.4 and 3.5) has been added.

Gentoo-Bug: https://bugs.gentoo.org/591292
Package-Manager: portage-2.3.1
Closes: https://github.com/gentoo/gentoo/pull/2502

Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

dev-python/python-xlib/Manifest

@@ -1 +1,2 @@
 DIST python-xlib-0.15rc1.tar.gz 188750 SHA256 823734489fc8c47113deb606fdc7142759d4c45546014255af8c5b8787b9accb SHA512 e27f56e0d76fac534e6754b1e64316636b49859eb6c9ceef5952c8b42cf53bc798a705fa54c283c896324d9a23778beec583cb62984a6a43b024643a70f3fe3a WHIRLPOOL bdca7c97cfbf438cce6297d5d035488986886d95f6f80014c9d9b1966720b98600b13f6dc09b6aed209787833e3174a0bf8444c3ba9c46e9f106051b978d322b
+DIST python-xlib-0.17.tar.bz2 185804 SHA256 600e820e340528184a873c5c4dccc67d7e4c34d658606fffadb02f32b5edd38a SHA512 0c3346de00304f8028492ef1eb7a9d0e22e750f9d51714e5a458e734218ef69760a07a5b3436eda70c9a952d52848757e1ead520bdaaefaf1b6575e0cc299b88 WHIRLPOOL 81d73930abe5277a0daa7ab2b245172315eff311d30dff532a9c10997d7d7ffd8de9d7f8a0ee2992b18f5ad58734511b30916c9c3f45ba34555f09750710c1e6

dev-python/python-xlib/python-xlib-0.17.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="A fully functional X client library for Python, written in Python"
+HOMEPAGE="https://github.com/python-xlib/python-xlib"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="doc"
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]"
+
+# DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	sed -e 's:make:$(MAKE):g' -i doc/Makefile || die
+	cp -r "${FILESDIR}"/defs doc/src/ || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		cd doc || die
+		VARTEXFONTS="${T}"/fonts emake html
+	fi
+}
+
+python_test() {
+	cd test || die
+
+	local t
+	for t in *.py; do
+		"${EPYTHON}" "${t}" || die
+	done
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/html/. )
+	distutils-r1_python_install_all
+}