gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-07-29 10:18:08 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/aiohttp: version bump to 3.0.6

Browse Source
This commit is contained in:
Tim Harder
2018-03-06 07:29:55 -05:00
parent bf114895d5
commit 308abc97ae
2 changed files with 71 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/aiohttp/Manifest
View File

@@ -3,3 +3,4 @@ DIST aiohttp-1.3.5.tar.gz 527432 BLAKE2B 6420ecc1eaa29713643dbe9a05061df5277f10e
DIST aiohttp-2.3.10.tar.gz 848324 BLAKE2B c32a7be3f3d9ba0bd1308c5bea779a10e177b9c018a03fb3cf95d1a1392180f3b4ea294dc23e2e946cc1065d16d212a169ec262a79034ae94b3a5067fbaf362c SHA512 e4ea725bbd3d7d749f2ec21eea1ff9f5c836fbeaa17ad72f77e378c69b008448e57503175bee6adff86110f65edc915cb6368df3011d1d9d61cf47718b086be0
DIST aiohttp-2.3.2.tar.gz 841030 BLAKE2B a291baa1c5e915815ec80ea1cbd8434b31f4098eeff20767898fc73d75c6194df4bc2a5d21147a8e5c506f5bc377e79b6e8937ce65b9c73616366f439e542c1a SHA512 e481787fec8c9f21d49978b378fb5ef8c06d06cd7a6625fc36c5d4a035e9047f4ed0e38b25b613f1b685ca40e18c796376750f4ac0970fcd1d72ca7fbe31d13f
DIST aiohttp-3.0.5.tar.gz 738000 BLAKE2B 742d3647a61e21ed8fc7a0a344337c5260b2bc34ffeb84660ddc031ff3872c97d7cadb66a02a4bc2531ca22b54fc1b93e8cf321d696cf4ec21a60170631d866c SHA512 650dbe3e5363c259fc5ce95baec4fd16ca2fd0836236d7d8f65597346f72fec29f803e037ffd6fc4e726a28a973aa09b0a3874a685516fbc4e843ad7f0f08b7b
DIST aiohttp-3.0.6.tar.gz 738111 BLAKE2B 28a3560a7b351ee974db8bbdd372798e01696e66660b6330707c542253c4d8a0405e6e8c2c8ec03c3b0ea8b548516ffb2dfe14b800b5f17e908991244bfd9335 SHA512 43f1b3c2da1bc57ac6e83a01abb3568b71ed5514e9331aaba4b691ff036d2d3e72eeddadd0f2f20608fa1f622a673ce1d4489bced2096ae546a350ad5f438d0d

70
dev-python/aiohttp/aiohttp-3.0.6.ebuild Normal file
View File

@@ -0,0 +1,70 @@
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
PYTHON_COMPAT=( python3_{5,6} )
inherit distutils-r1
DESCRIPTION="http client/server for asyncio"
HOMEPAGE="https://pypi.python.org/pypi/aiohttp"
SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz -> ${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc test"
CDEPEND="
>=dev-python/async_timeout-1.2.0[${PYTHON_USEDEP}]
>=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
dev-python/chardet[${PYTHON_USEDEP}]
>=dev-python/multidict-4.0.0[${PYTHON_USEDEP}]
>=dev-python/yarl-1.0[${PYTHON_USEDEP}]
dev-python/idna-ssl[${PYTHON_USEDEP}]
"
DEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/cython[${PYTHON_USEDEP}]
doc? (
>=dev-python/alabaster-0.6.2[${PYTHON_USEDEP}]
dev-python/sphinxcontrib-asyncio[${PYTHON_USEDEP}]
dev-python/sphinxcontrib-newsfeed[${PYTHON_USEDEP}]
dev-python/sphinxcontrib-spelling[${PYTHON_USEDEP}]
dev-python/sphinx[${PYTHON_USEDEP}]
)
test? (
${CDEPEND}
>=dev-python/pytest-3.4.0[${PYTHON_USEDEP}]
dev-python/pytest-mock[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
www-servers/gunicorn[${PYTHON_USEDEP}]
)
"
RDEPEND="${CDEPEND}"
DOCS=( CHANGES.rst CONTRIBUTING.rst CONTRIBUTORS.txt HISTORY.rst README.rst )
PATCHES=( "${FILESDIR}"/${PN}-3.0.5-tests.patch )
python_prepare_all() {
# skip failing tests until cause is determined
rm tests/{test_pytest_plugin.py,test_worker.py} || die
distutils-r1_python_prepare_all
}
python_compile_all() {
use doc && emake -C docs html
}
python_test() {
#PYTHONPATH="${PWD}:${PYTHONPATH}" py.test -v tests || die "Tests failed under ${EPYTHON}"
esetup.py test
}
python_install_all() {
use doc && local HTML_DOCS=( docs/_build/html/. )
distutils-r1_python_install_all
}