gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-31 09:08:08 -07:00
Code Issues Projects Releases Wiki Activity

dev-lua/luacov: bump to version 0.14.0, migrate to lua eclass

Browse Source 
Closes: https://bugs.gentoo.org/752636
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
This commit is contained in:
Conrad Kostecki
2020-12-01 12:56:26 +01:00
parent 63a2f5bf2f
commit 3029a542b1
5 changed files with 105 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-lua/luacov/Manifest
View File

@@ -1 +1,2 @@
DIST luacov-0.14.0.tar.gz 49571 BLAKE2B 2248fc00e1af0a1cdec923bbe6150ae682cc1ba814c77f21bc86269d723ea80542fb48fe62980de2527040598b7b9c87f92f146d6c62abde06651fa6733c75c5 SHA512 44ea158ce597f705d80b9768676e401804daea91b9c2afb146a8d25aae612e895e4f42a29c4b7b3438659c596fa500af5d23b66b7f3477459747ad06ca9b7ffa
DIST luacov-0.8.tar.gz 33613 BLAKE2B 942c47de25dbd53de445e1ed1fa924f1be278da4c3b134e4a603f4a5ab5090f87d762c48163cf82ed9bab585e35b0528c330b3dc849e0043ccc96532107c8a94 SHA512 03d6ee519a570ff0430bcc32f547b9beb01691bd8c7ad8655e78d732223c6c25e4a63d816fd99640568251b836d5e3cc736bd5d780f5ecd3986d855ed5edfa11

53
dev-lua/luacov/luacov-0.14.0-r100.ebuild Normal file
View File

@@ -0,0 +1,53 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
LUA_COMPAT=( lua5-{1..3} luajit )
inherit lua
DESCRIPTION="A simple coverage analyzer for Lua scripts"
HOMEPAGE="https://github.com/keplerproject/luacov"
SRC_URI="https://github.com/keplerproject/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
IUSE="test"
REQUIRED_USE="${LUA_REQUIRED_USE}"
RESTRICT="!test? ( test )"
RDEPEND="${LUA_DEPS}"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
test? (
dev-lua/busted[${LUA_USEDEP}]
${RDEPEND}
)
"
HTML_DOCS=( "doc/." )
lua_src_test() {
busted --lua=${ELUA} || die
}
src_test() {
lua_foreach_impl lua_src_test
}
lua_src_install() {
insinto "$(lua_get_lmod_dir)"
doins src/luacov.lua
doins -r src/luacov
}
src_install() {
lua_foreach_impl lua_src_install
dobin src/bin/luacov
einstalldocs
}

46
dev-lua/luacov/luacov-0.14.0.ebuild Normal file
View File

@@ -0,0 +1,46 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit toolchain-funcs
DESCRIPTION="A simple coverage analyzer for Lua scripts"
HOMEPAGE="https://github.com/keplerproject/luacov"
SRC_URI="https://github.com/keplerproject/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
IUSE="luajit test"
REQUIRED_USE="${LUA_REQUIRED_USE}"
RESTRICT="!test? ( test )"
RDEPEND="
luajit? ( dev-lang/luajit:2 )
!luajit? ( dev-lang/lua:0 )
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
test? (
dev-lua/busted
${RDEPEND}
)
"
HTML_DOCS=( "doc/." )
src_test() {
busted --lua="$(usex luajit 'luajit' 'lua')" || die
}
src_install() {
dobin src/bin/luacov
insinto "$($(tc-getPKG_CONFIG) --variable INSTALL_LMOD $(usex luajit 'luajit' 'lua'))"
doins src/luacov.lua
doins -r src/luacov
einstalldocs
}

4
dev-lua/luacov/metadata.xml
View File

@@ -5,6 +5,10 @@
<email>williamh@gentoo.org</email>
<name>William Hubbs</name>
</maintainer>
<maintainer type="person">
<email>conikost@gentoo.org</email>
<name>Conrad Kostecki</name>
</maintainer>
<upstream>
<remote-id type="github">keplerproject/luacov</remote-id>
</upstream>