dev-cpp/folly: add 2022.03.07.00

Signed-off-by: Sam James <sam@gentoo.org>

dev-cpp/folly/Manifest

@@ -1 +1,2 @@
 DIST folly-2022.02.28.00.tar.gz 3600258 BLAKE2B 5943b0e4b6178c8293714f673ed289daed26b1dad22dcb52dc80475f385961cf0a690accc44139f245f2df5cf10c0bdb5638c8bed52cb97fefd3ad6d8dc147b8 SHA512 91ee21e463ffc6eee3b0e5e0244721a9612337b9afe92645556a154f521aec1070f4f381962247bb9bf11592efb5b8bb01f70d1a66acd3444967538062dfe826
+DIST folly-2022.03.07.00.tar.gz 3604306 BLAKE2B fe255678d6f827c82ada3e136742d07bd62dfb81c1250ca6bae9a4f3e1f015904032da8de1488342da1326fa520b448c63a59ef7e0139ecb0844a1ae19c1dfed SHA512 e63eff137711ca71b5a78469e4feff1b4e7b65465413eefb91b7c0cb26b94e1d581a305a9df9937ce05bcd8af3dc465adb816ad95538689811d8ab5b5b9f269f

dev-cpp/folly/folly-2022.03.07.00.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake toolchain-funcs
+
+DESCRIPTION="An open-source C++ library developed and used at Facebook"
+HOMEPAGE="https://github.com/facebook/folly"
+SRC_URI="https://github.com/facebook/folly/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="llvm-libunwind test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="app-arch/bzip2
+	app-arch/lz4:=
+	app-arch/snappy:=
+	app-arch/xz-utils
+	app-arch/zstd:=
+	dev-cpp/gflags:=
+	dev-cpp/glog[gflags]
+	dev-libs/boost:=[context,threads(+)]
+	dev-libs/double-conversion:=
+	dev-libs/libaio
+	dev-libs/libevent:=
+	dev-libs/libfmt:=
+	dev-libs/libsodium:=
+	dev-libs/openssl:=
+	sys-libs/liburing:=
+	sys-libs/zlib
+	llvm-libunwind? ( sys-libs/llvm-libunwind:= )
+	!llvm-libunwind? ( sys-libs/libunwind:= )"
+# libiberty is linked statically
+DEPEND="${RDEPEND}
+	sys-libs/binutils-libs"
+BDEPEND="test? ( sys-devel/clang )"
+
+pkg_setup() {
+	if use test && [[ ${BUILD_TYPE} != "binary" ]] && ! tc-is-clang ; then
+		ewarn "Forcing build with Clang due to GCC bug (because tests are enabled)"
+		ewarn "(https://gcc.gnu.org/bugzilla/show_bug.cgi?id=104008)"
+
+		export CC=${CHOST}-clang
+		export CXX=${CHOST}-clang++
+	fi
+}
+
+src_configure() {
+	# TODO: liburing could in theory be optional but fails to link
+
+	local mycmakeargs=(
+		-DLIB_INSTALL_DIR="$(get_libdir)"
+
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}