From 2f21b415220b960fd62a7f93e91becd87e7b0252 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 17 Jun 2025 05:18:52 +0200
Subject: [PATCH] dev-python/pdm: Bump to 2.25.2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pdm/Manifest          |  1 +
 dev-python/pdm/pdm-2.25.2.ebuild | 81 ++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 dev-python/pdm/pdm-2.25.2.ebuild

diff --git a/dev-python/pdm/Manifest b/dev-python/pdm/Manifest
index e76902b371839..b4f33c0e91598 100644
--- a/dev-python/pdm/Manifest
+++ b/dev-python/pdm/Manifest
@@ -1 +1,2 @@
 DIST pdm-2.25.1.tar.gz 2662443 BLAKE2B 8032152344c7369c0242a6b6854d94ea29617ca5ef07ea5bb4cbf98e05d7a03240944b367a78f5733a72590739b678fcd6a991cb014d2d43c1e723505255736e SHA512 dcd4c9a97053001b6a9760fcd5203da64e7c423d9f0273bca156057505ab7aaada35631cd4d90474854cf55e5a67c8ca48c1de75660a0067709ef61f1be1754d
+DIST pdm-2.25.2.tar.gz 2662555 BLAKE2B 1f0c6653aacc7acc281d0dddfc76a7c47db412bc9b74f69d6ea57a787a2f52f81d6b2d8a8db08c1653135dbb986441a3ffefa9b5fc7f3e33e13c65a5bcd79aee SHA512 e68a60779445fd8007ede2f59ea47318d4eb64a9f5ab3561f4e46ab94c209d87bc564103b4bd0bd4229e5c1a9d55340207d18d13ced94aa78d3d82a4facdaf04
diff --git a/dev-python/pdm/pdm-2.25.2.ebuild b/dev-python/pdm/pdm-2.25.2.ebuild
new file mode 100644
index 0000000000000..5e9e71dd639ec
--- /dev/null
+++ b/dev-python/pdm/pdm-2.25.2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pdm-project.org/
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/dep-logic-0.5[${PYTHON_USEDEP}]
+	<dev-python/findpython-1[${PYTHON_USEDEP}]
+	>=dev-python/findpython-0.6.0[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	>=dev-python/hishel-0.0.32[${PYTHON_USEDEP}]
+	>=dev-python/httpcore-1.0.6[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	>=dev-python/id-1.5.0[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pbs-installer-2025.06.06[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.1[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	>=dev-python/truststore-0.9[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.17.5[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+		dev-python/pytest-httpx[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/uv
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -i -e 's:,<[0-9.a]*::' pyproject.toml || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+		# unhappy about extra packages being installed?
+		# (also fails randomly in venv)
+		tests/cli/test_build.py::test_build_with_no_isolation
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest  -m "not network and not integration and not path" \
+		-p pytest_mock -p pytest_httpx -p pytest_httpserver
+}