dev-python/pushbullet-py: bump to 0.11.0, add py3.6

Package-Manager: Portage-2.3.6, Repoman-2.3.3
Closes: https://github.com/gentoo/gentoo/pull/5200

dev-python/pushbullet-py/Manifest

@@ -1 +1,2 @@
 DIST pushbullet-py-0.10.0.tar.gz 18929 SHA256 318c05f743c94803fc2e2cd786fe258e968d1bef26d05039f005763b0f23e703 SHA512 2e259b76413c5e644350a891678eb98f761e56b18f5a06a9d7cc34353c7c7ee67fa875aed575b1b005782b21f4440d682db5c09be7033d52b7b9cf41e9120123 WHIRLPOOL fd0f98887e73dd04c9510550dd97d711319844f82b7e7d34c35e0db886f08df0d4b800a3f95f2e61de4b909079f2eda4813950743f935c08f875f0cc6e2d227f
+DIST pushbullet.py-0.11.0.tar.gz 21653 SHA256 aa9dc7bb46e083e3497d46241154f12944a8f540e29d150330ca94db0b453b8d SHA512 b236f30b99e5bb79eff183529716c1c8f83cfd2526fdf50d86041eb6d3fcd6670d0c4dce407ae6e50aea0fa96d6a5527af980148f0c71ef758c480f972ad9659 WHIRLPOOL 425ac3d558b67e7ea621adb84a6d40876f159e70d22082c3985e0a59d7d8c25d7128f74c404716cdc2b53df3907bf365cb9582e3488efb098ec8e08ccf5789e1

dev-python/pushbullet-py/pushbullet-py-0.11.0.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+DESCRIPTION="A simple python client for pushbullet.com"
+HOMEPAGE="https://github.com/randomchars/pushbullet.py"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_test() {
+	# skip tests which require network access
+	PUSHBULLET_API_KEY= py.test \
+		-k "not (test_auth or test_decryption)" \
+		|| die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r example/.
+	fi
+	distutils-r1_python_install_all
+}