From 2ebbb80c8cba2c3417727db70a027b5518a413ee Mon Sep 17 00:00:00 2001
From: Alfred Wingate <parona@protonmail.com>
Date: Sun, 1 Jun 2025 01:56:19 +0300
Subject: [PATCH] dev-python/lap: new package, add 0.5.12

Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/42378
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-python/lap/Manifest          |  1 +
 dev-python/lap/lap-0.5.12.ebuild | 45 ++++++++++++++++++++++++++++++++
 dev-python/lap/metadata.xml      | 11 ++++++++
 3 files changed, 57 insertions(+)
 create mode 100644 dev-python/lap/Manifest
 create mode 100644 dev-python/lap/lap-0.5.12.ebuild
 create mode 100644 dev-python/lap/metadata.xml

diff --git a/dev-python/lap/Manifest b/dev-python/lap/Manifest
new file mode 100644
index 0000000000000..b5c5f766b71ac
--- /dev/null
+++ b/dev-python/lap/Manifest
@@ -0,0 +1 @@
+DIST lap-0.5.12.tar.gz 1520169 BLAKE2B ce68ddd14304b930044a94ff7362b00724ca8ce89d5fa0189437a393cff5911ac74cc45056ba152780000f7f4c691e73269cd711f20f5f693f5699918c0c4428 SHA512 a8ba1883e06b04a41cebb53999bcc7321748036958fde1ab37a2194b43104a84d0315bea89b21aaae7556cc3f573d95bf30107dc4045af301134dd10319b7d53
diff --git a/dev-python/lap/lap-0.5.12.ebuild b/dev-python/lap/lap-0.5.12.ebuild
new file mode 100644
index 0000000000000..bbc6a81d3bab6
--- /dev/null
+++ b/dev-python/lap/lap-0.5.12.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Linear Assignment Problem solver (LAPJV/LAPMOD)"
+HOMEPAGE="
+	https://github.com/gatagat/lap
+	https://pypi.org/project/lap/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/numpy-1.21.6[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.23.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Don't install tests and keep them in a separate location
+	# https://projects.gentoo.org/python/guide/test.html#importerrors-for-c-extensions
+	mv lap/tests tests || die
+	sed -e '/tests_package =/d' \
+		-e '/packages =/ { s/, tests_package// }' \
+		-i setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	rm -rf lap || die
+	epytest
+}
diff --git a/dev-python/lap/metadata.xml b/dev-python/lap/metadata.xml
new file mode 100644
index 0000000000000..8169140e0ab69
--- /dev/null
+++ b/dev-python/lap/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">gatagat/lap</remote-id>
+		<remote-id type="pypi">lap</remote-id>
+	</upstream>
+</pkgmetadata>