From 2dc4109effae470d3fbc990c1eb7353371d9727a Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 7 Oct 2022 08:36:51 +0200
Subject: [PATCH] dev-python/black: Bump to 22.10.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/black/Manifest             |  1 +
 dev-python/black/black-22.10.0.ebuild | 55 +++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)
 create mode 100644 dev-python/black/black-22.10.0.ebuild

diff --git a/dev-python/black/Manifest b/dev-python/black/Manifest
index 39c3d55712204..78ff6ce590551 100644
--- a/dev-python/black/Manifest
+++ b/dev-python/black/Manifest
@@ -1 +1,2 @@
+DIST black-22.10.0.gh.tar.gz 1177403 BLAKE2B c8185f1cd16bf890ad0c75a50ccf211eb8e0d50a62654abc30ff6404818c323a08551d9a79194d05df6f4f92c4c7bca43b1d317243d84542f8eda3dcc0b2895c SHA512 ec03dd7b29becaabac1393d636ba394182c4fdacc57112980c76485f05e8fdf41e23cf8dc72dfdf530a5f060e709a0bc9d60d797e897020ae036e0a5410fc4b2
 DIST black-22.8.0.gh.tar.gz 1173503 BLAKE2B 851e2dedf35871dc07caaafbffa15aa91e18640a352df717e19dc98b48134af21343e36faf90899fedd700149f988f5385c18c2d01ca330ef6e7a721cbe41a38 SHA512 f9db2079aedb14a8d9388a2c0997ffd55c74636d487ef7a3ad86fcd038a3e5d3f63168a1bca266b3e3128cd8590a641bd4259be9c238a8df968c3c085682d3b6
diff --git a/dev-python/black/black-22.10.0.ebuild b/dev-python/black/black-22.10.0.ebuild
new file mode 100644
index 0000000000000..e3ddc4ea1c0c3
--- /dev/null
+++ b/dev-python/black/black-22.10.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# py3.11 blocked by mypy_extensions
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="The uncompromising Python code formatter"
+HOMEPAGE="
+	https://black.readthedocs.io/en/stable/
+	https://github.com/psf/black/
+	https://pypi.org/project/black/
+"
+SRC_URI="
+	https://github.com/psf/black/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/click-8.0.0[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-3.10.0.0[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/aiohttp-3.7.4[${PYTHON_USEDEP}]
+		dev-python/aiohttp-cors[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+pkg_postinst() {
+	optfeature "blackd - HTTP API for black" "dev-python/aiohttp dev-python/aiohttp-cors"
+}