From 2d58c1dcec12c847c3d249d73dcb2f031a47ad07 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 2 Jun 2023 10:49:47 +0200
Subject: [PATCH] dev-python/pdm-backend: Rename of dev-python/pdm-pep517,
 2.0.7
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pdm-backend/Manifest               |  1 +
 dev-python/pdm-backend/metadata.xml           | 13 ++++
 .../pdm-backend/pdm-backend-2.0.7.ebuild      | 65 +++++++++++++++++++
 3 files changed, 79 insertions(+)
 create mode 100644 dev-python/pdm-backend/Manifest
 create mode 100644 dev-python/pdm-backend/metadata.xml
 create mode 100644 dev-python/pdm-backend/pdm-backend-2.0.7.ebuild

diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
new file mode 100644
index 0000000000000..185672dc645fb
--- /dev/null
+++ b/dev-python/pdm-backend/Manifest
@@ -0,0 +1 @@
+DIST pdm-backend-2.0.7.gh.tar.gz 131573 BLAKE2B 69750ccada51e09886d39b37fe00f842ccc70d1b7fd301ce2a72601f72e6d8d01ed0eef43ce7d9a6d9094e2c547965e91013dec7e7692479a5c9e2d0b7025c83 SHA512 7bfbdd52af739d6b6c85468888b44144fbc4fe542e758b62a09a85d7a503a980a82ef3450ac5c234005bbd7dd399ab7ddbe9b7948820b7ba7e8558c5b0fd9581
diff --git a/dev-python/pdm-backend/metadata.xml b/dev-python/pdm-backend/metadata.xml
new file mode 100644
index 0000000000000..b27d716c3e920
--- /dev/null
+++ b/dev-python/pdm-backend/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">pdm-backend</remote-id>
+		<remote-id type="github">pdm-project/pdm-backend</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/pdm-backend/pdm-backend-2.0.7.ebuild b/dev-python/pdm-backend/pdm-backend-2.0.7.ebuild
new file mode 100644
index 0000000000000..403a89a308453
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.0.7.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-backend/
+	https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/packaging-22.0[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	$(python_gen_cond_dep '
+		>=dev-python/importlib-metadata-3.6[${PYTHON_USEDEP}]
+	' 3.9)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r src/pdm/backend/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.backend\._vendor\.:from :' \
+		-e 's:from pdm\.backend\._vendor ::' \
+		-e 's:import pdm\.backend\._vendor\.:import :' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}