dev-java/openjdk-jre-bin: add 17.0.16_p8

Bug: https://bugs.gentoo.org/960284
Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Part-of: https://github.com/gentoo/gentoo/pull/43054
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

dev-java/openjdk-jre-bin/Manifest

@@ -1,5 +1,6 @@
 DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.27_6.tar.gz 43401920 BLAKE2B d71de5aabb4dbb04fd8861c870fd2c196a63920002c44fa777c6ce69ab4c898a72a5573bc461de6c7b233718adcfdee28eac6e5d59abaff0ba145bea7090fdf3 SHA512 0bf686cb3dd9c01a1391ad74c8bce799063a0d44bec7cd2bd68f90aa8bdda65cd8897f95b52878c4466865cfdffab862269b37e73e8907f1404b9bb5d52b1df9
 DIST OpenJDK17U-jre_x64_linux_hotspot_17.0.15_6.tar.gz 46098776 BLAKE2B 02114ee357c8a64be625d0ba2429a37d86bca89d70d9e5cf8f66069c039894fe88f8cf7e04547c56b6b1a5cc9d6d7b90992ca2177a4e72dd50ae4725ab32cec4 SHA512 e8812a916e7310272bada9cb8912102c106b20a7c86c8da78a111ef72b0d284e79e6fa01ba8e862b3a22d751b96935d970b90f79b2ed7a933ab28acb9b0a292f
+DIST OpenJDK17U-jre_x64_linux_hotspot_17.0.16_8.tar.gz 46121196 BLAKE2B efd0e35320e4393982148128f3f32ef92de6801629059267f655f6ea85d615c5266f1f06679fe8b7526ac72acf9bc642bed8ddadff132b9625ef6c54e36fae82 SHA512 69956896ee2826f24928be551d687baac0061033ea221a311d6196ccb0e6dc1f2fbfd6f76210081cb6e5e10020042e23a3c1defbde947cd6777405e036fee097
 DIST OpenJDK21U-jre_x64_linux_hotspot_21.0.7_6.tar.gz 51863597 BLAKE2B adc7d8a092eda560b7804e5f3b96620b6060c97e7ad409320e096de8e4f4252b29e03c33a6e39d4c834ee8c8b64a256f0711525db4a856171285700293333bb7 SHA512 3318754a0be4afbc538d3646579f2ca0e143fae60475fe0d288ecdd2104ddf1914e4f7a0e1d6c18bf575de1e987a7455a3599504c08635e76d908579fa014e23
 DIST OpenJDK21U-jre_x64_linux_hotspot_21.0.8_9.tar.gz 51942501 BLAKE2B b5cd15d1a34640f9ad32c5b3af221cbb2af67bd00485a0d0891e4b39bf1afe094b0f611b092adb62c9d1afacb09c4acee67b52fb2d7689e947a7593a2fc2fc2f SHA512 4e2f5177404c1e52f5d417c1fa5505db9397d04c6507365e8fb22c7e3008eb73173749b18825a48a9e699a968c1ff71dc2d04c769eb950edc34f912940faf2d5
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u452b09.tar.gz 41420532 BLAKE2B cb957b8ec18bf1e97ffc800adca15af83ecd1fb7cac5c059d7b9d8043706438f635db02dcdfd6fb93686eb5c5512e773bc73993002f959404b1a2036d5e4ae29 SHA512 cafe940d184f2314b98543d341487a9b325cc790417d7b26f637d814705be79bac291b046b5a00a96cff23b9e16adf33aaa39c17e824283bad8c5c003a0b7ae1

dev-java/openjdk-jre-bin/openjdk-jre-bin-17.0.16_p8.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/adoptium/temurin${SLOT}-binaries/releases/download/jdk-${MY_PV}/OpenJDK${SLOT}U-jre_${1}_linux_hotspot_${MY_PV//+/_}.tar.gz
+		)"
+}
+
+MY_PV=${PV/_p/+}
+SLOT=${MY_PV%%[.+]*}
+
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by Eclipse Temurin"
+HOMEPAGE="https://adoptium.net/"
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+IUSE="alsa cups headless-awt selinux"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk-${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${PN}-${SLOT}"
+	local ddest="${ED}/${dest#/}"
+
+	# https://bugs.gentoo.org/922741
+	docompress "${dest}/man"
+
+	# Not sure why they bundle this as it's commonly available and they
+	# only do so on x86_64. It's needed by libfontmanager.so. IcedTea
+	# also has an explicit dependency while Oracle seemingly dlopens it.
+	rm -vf lib/libfreetype.so || die
+
+	# Oracle and IcedTea have libjsoundalsa.so depending on
+	# libasound.so.2 but AdoptOpenJDK only has libjsound.so. Weird.
+	if ! use alsa ; then
+		rm -v lib/libjsound.* || die
+	fi
+
+	if use headless-awt ; then
+		rm -v lib/lib*{[jx]awt,splashscreen}* || die
+	fi
+
+	rm -v lib/security/cacerts || die
+	dosym -r /etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	java-vm_install-env "${FILESDIR}"/${PN}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+	java-vm-2_pkg_postinst
+}