From 2cc967ca5bc12d04b5f154f930d58f633d741fa1 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 16 Aug 2025 07:13:58 +0200
Subject: [PATCH] dev-python/rq: Bump to 2.5.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/rq/Manifest        |  1 +
 dev-python/rq/rq-2.5.0.ebuild | 81 +++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 dev-python/rq/rq-2.5.0.ebuild

diff --git a/dev-python/rq/Manifest b/dev-python/rq/Manifest
index cb63539c0d9e3..35b871ba37b01 100644
--- a/dev-python/rq/Manifest
+++ b/dev-python/rq/Manifest
@@ -1 +1,2 @@
 DIST rq-2.4.1.tar.gz 664540 BLAKE2B e5e8617c165c555b150fc3e8d6eacdfb697d6490cf5d972eaf78437a92d70c80e3a8c36e399e85716f30bf0a80a87f49602abc50ad98074aa228dcfb2c99ad4a SHA512 4a4dc8810f2cfda8ec7af722358ccf18b61fdd2898177224ca1d686f1d20483518419adc88027bb671bc38e605894244189c0c0c6eabbaab0550a4ae632457da
+DIST rq-2.5.0.tar.gz 666978 BLAKE2B 951c34282caef2983e58edc6fe3f92209941baa4d32767dd8d6f068e866ba569320bf7daaaec983e7e9c74e51eea47661c1114828b1cb57114e2554d5fc8f796 SHA512 fb76fdf9f1f73b2ce2a59b049a369749695b38f58ee62c14727d2b118fe97ca471d7113bd8825d8aa8661541b4b8b9355a3421c9eed86c2477433e8a49151ad9
diff --git a/dev-python/rq/rq-2.5.0.ebuild b/dev-python/rq/rq-2.5.0.ebuild
new file mode 100644
index 0000000000000..43411a0947b79
--- /dev/null
+++ b/dev-python/rq/rq-2.5.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple, lightweight library for creating and processing background jobs"
+HOMEPAGE="
+	https://python-rq.org/
+	https://github.com/rq/rq/
+	https://pypi.org/project/rq/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/click-5.0[${PYTHON_USEDEP}]
+	dev-python/croniter[${PYTHON_USEDEP}]
+	>=dev-python/redis-4.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# strip pin
+	sed -i -e '/dependencies/s:,!=[0-9.]*::' pyproject.toml || die
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	# Spawn Redis itself for testing purposes
+	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the actual tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires <sentry-sdk-2
+		tests/test_sentry.py::TestSentry::test_failure_capture
+		# hang
+		tests/test_commands.py::TestCommands::test_shutdown_command
+		tests/test_worker_pool.py::TestWorkerPool::test_check_workers
+		tests/test_worker_pool.py::TestWorkerPool::test_reap_workers
+		tests/test_dependencies.py::TestDependencies
+		# already present in older versions
+		tests/test_spawn_worker.py::TestWorker::test_work_and_quit
+	)
+
+	epytest
+}