dev-python/dulwich: Bump to 0.20.15

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/dulwich/Manifest

@@ -1 +1,2 @@
+DIST dulwich-0.20.15.tar.gz 391841 BLAKE2B 8db19f84154dff0851fd16bc534d92b506c93a93d7180079bc9829a2c81bbb25b04b234770e62ddab82440973d0702b8523896a9db90d771d8cc915b6321cdaa SHA512 a4e746099a90ea2d7eb5f0309508a4f625d41732bdda78997fab07b38ea2ecbd2c2aed08c8ef05b1b73fe3e2ba9b8c8cbf02270f8edbc6235d66cdee0317365c
 DIST dulwich-0.20.6.tar.gz 388660 BLAKE2B 1a193d03e0f21a9fdd125617823742b87e9bea74c73734da10eb79f1ecbec0263cb90224f78413c724db8998f4d06ff6c448e7a6d50ce760ba1545f3321b95d8 SHA512 2f11ce9a1c716fb4242f1f93fce92f756bd93ed8f0951fc2e6b3fb18b0a495b0f372966149fca587efcafc0eaf00e9fbfcfd957442a96cc2004eb66cb7f0773e

dev-python/dulwich/dulwich-0.20.15.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend  # tests use setuptools, setup uses if found
+
+inherit distutils-r1
+
+DESCRIPTION="Pure-Python implementation of the Git file formats and protocols"
+HOMEPAGE="https://github.com/jelmer/dulwich/ https://pypi.org/project/dulwich/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		!hppa? ( !ia64? (
+			dev-python/gevent[${PYTHON_USEDEP}]
+			dev-python/geventhttpclient[${PYTHON_USEDEP}]
+		) )
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/python-fastimport[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs
+
+python_test() {
+	# remove interference from the tests that do stuff like user.name
+	unset GIT_AUTHOR_NAME GIT_AUTHOR_EMAIL GIT_AUTHOR_DATE \
+		GIT_COMMITTER_NAME GIT_COMMITTER_EMAIL GIT_COMMITTER_DATE EMAIL
+	# Do not use make check which rebuilds the extension and uses -Werror,
+	# causing unexpected failures.
+	"${EPYTHON}" -m unittest -v dulwich.tests.test_suite \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}