games-action/supertuxkart: drop 1.3

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

games-action/supertuxkart/Manifest

@@ -1,3 +1,2 @@
-DIST SuperTuxKart-1.3-src.tar.xz 627753500 BLAKE2B 3ffc86edf80adb27cd17a6ba796fb14d0660a1c14ff21c7908e5f965609c6f6a6b40270a21690cd1318d1003e07d90b4180c292252b1731d4cd6292fe12e6086 SHA512 42664390c844ebca0be9b2f2aeb3c9197c0c79a7c604707b32e81ef41aec10fa36f5950f06e1540ea6f75f6c7f8a8f7f80aeda48de3d101d991420f5b20530ed
 DIST SuperTuxKart-1.4-src.tar.xz 650010456 BLAKE2B dc85c77cdf8b8f7377b5771eb3b3edbe20f6949c99f710ca70506c09152e7a846b3d3239f185d23c9fdf0477da417bacc644793b3407aed1e68fc41ced41a71e SHA512 e88f3fb5ccdb38d0ef75e92d73b43c5cc7a1f6c76ac9502033df099a00d6dc3e86b2c5442b806237d2420c44ada7dd23a2c90ecf94785a44d2348c933770a5ab
 DIST supertuxkart.png 4435 BLAKE2B b48b95e1cdebe930837cc784c4c5e9a089a69077e2fcfed15fe5e8c4d649a0f8024769b2f2102bbaea3a94eb21f4b58b5d291b97493266c3c5c8d7335cf69a80 SHA512 a180332f79220431922fa8b351cb476ebc5d9d1df09f20707eb3bdd7002fd264cb027b8190c73c5221050e6e8601beb6758a5809d05aedfb18f0bdb426f47eda

games-action/supertuxkart/supertuxkart-1.3.ebuild

@@ -1,99 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake desktop flag-o-matic xdg
-
-MY_P="SuperTuxKart-${PV}-src"
-DESCRIPTION="A kart racing game starring Tux, the linux penguin (TuxKart fork)"
-HOMEPAGE="https://supertuxkart.net/"
-SRC_URI="https://github.com/${PN}/stk-code/releases/download/${PV}/${MY_P}.tar.xz
-	mirror://gentoo/${PN}.png"
-
-LICENSE="GPL-2 GPL-3 CC-BY-SA-3.0 CC-BY-SA-4.0 CC0-1.0 public-domain ZLIB"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="debug nettle recorder sqlite wiimote"
-
-# don't unbundle irrlicht and bullet
-# both are modified and system versions will break the game
-# https://sourceforge.net/p/irrlicht/feature-requests/138/
-
-RDEPEND="
-	dev-cpp/libmcpp
-	sqlite? ( dev-db/sqlite:3 )
-	dev-libs/angelscript:=
-	media-libs/freetype:2
-	media-libs/glew:0=
-	media-libs/harfbuzz:=
-	media-libs/libpng:0=
-	media-libs/libsdl2[opengl,video]
-	media-libs/libvorbis
-	media-libs/openal
-	net-libs/enet:1.3=
-	net-misc/curl
-	sys-libs/zlib
-	virtual/glu
-	virtual/jpeg:0
-	virtual/libintl
-	virtual/opengl
-	x11-libs/libX11
-	x11-libs/libXxf86vm
-	nettle? ( dev-libs/nettle:= )
-	!nettle? (
-		>=dev-libs/openssl-1.0.1d:0=
-	)
-	recorder? ( media-libs/libopenglrecorder )
-	wiimote? ( net-wireless/bluez )"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	sys-devel/gettext
-	virtual/pkgconfig"
-
-S="${WORKDIR}/${MY_P}"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.1-irrlicht-arch-support.patch
-	"${FILESDIR}"/${PN}-1.3-irrlicht-system-libs.patch
-)
-
-src_prepare() {
-	cmake_src_prepare
-}
-
-src_configure() {
-	# -Werror=strict-aliasing
-	# https://bugs.gentoo.org/858521
-	# https://github.com/supertuxkart/stk-code/issues/5035
-	#
-	# The issue is bundled code from sci-physics/bullet which is unlikely to
-	# be debundled.
-	#
-	# Do not trust with LTO either.
-	append-flags -fno-strict-aliasing
-	filter-lto
-
-	local mycmakeargs=(
-		-DUSE_SQLITE3=$(usex sqlite)
-		-DUSE_SYSTEM_ANGELSCRIPT=ON
-		-DUSE_SYSTEM_ENET=ON
-		-DUSE_SYSTEM_SQUISH=OFF
-		-DUSE_SYSTEM_WIIUSE=OFF
-		-DUSE_IPV6=OFF # not supported by system enet
-		-DUSE_CRYPTO_OPENSSL=$(usex nettle no yes)
-		-DBUILD_RECORDER=$(usex recorder)
-		-DUSE_WIIUSE=$(usex wiimote)
-		-DSTK_INSTALL_BINARY_DIR=bin
-		-DSTK_INSTALL_DATA_DIR=share/${PN}
-		-DBUILD_SHARED_LIBS=OFF # build bundled libsquish as static library
-	)
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-	dodoc CHANGELOG.md
-
-	doicon -s 64 "${DISTDIR}"/${PN}.png
-}