diff --git a/dev-python/xmlsec/Manifest b/dev-python/xmlsec/Manifest
index ffdcb2898cd1..548953fd0093 100644
--- a/dev-python/xmlsec/Manifest
+++ b/dev-python/xmlsec/Manifest
@@ -1 +1,2 @@
 DIST python-xmlsec-1.3.16.gh.tar.gz 80406 BLAKE2B 1be23867ae44a108dc0596698b712a4d2c8cff4206a9518cab3960368f5242981b8c4e4ba70b9183c298e5a35d2ab823d926019d7292d0a697e7bd3127f88bcc SHA512 1ed39d613c8c656b8d6898730212a3c990f1ab5b807dfdacc0a1c9db1ffaf79cbcc403e771d19faebdf170de7dc886df5582ee8589b6d0d72e3cb9ddc193012a
+DIST python-xmlsec-1.3.17.gh.tar.gz 81176 BLAKE2B 7f03b3b732751d89ef6c7765190eeb4add26d7f3332465f47e7faaae5007b0ab204c5df7d60fc6886e1cb199757b22a50b89757bf4ad6aba56fd02cce739f5fc SHA512 97404eb61442872f2ae745a5e2789d87227087b8ea47509e51b639b708bd5f4a0eeafb60dd0cecd6d63af740cff0035dd4bd66ae3d5bdd2803bad6e96226de69
diff --git a/dev-python/xmlsec/xmlsec-1.3.17.ebuild b/dev-python/xmlsec/xmlsec-1.3.17.ebuild
new file mode 100644
index 000000000000..95ae13c809e1
--- /dev/null
+++ b/dev-python/xmlsec/xmlsec-1.3.17.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+MY_P=python-xmlsec-${PV}
+DESCRIPTION="Python bindings for the XML Security Library"
+HOMEPAGE="
+	https://github.com/xmlsec/python-xmlsec/
+	https://pypi.org/project/xmlsec/
+"
+SRC_URI="
+	https://github.com/xmlsec/python-xmlsec/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	dev-libs/libxml2:=
+	dev-libs/xmlsec:=[openssl]
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	dev-python/wheel[${PYTHON_USEDEP}]
+"
+
+EPYTEST_DESELECT=(
+	# Fragile based on black version?
+	tests/test_type_stubs.py::test_xmlsec_constants_stub
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+	export PYXMLSEC_OPTIMIZE_SIZE=
+	if use debug; then
+		# we don't want to use PYXMLSEC_ENABLE_DEBUG envvar,
+		# as it forces -O0
+		export CPPFLAGS="${CPPFLAGS} -DPYXMLSEC_ENABLE_DEBUG=1"
+	fi
+}