diff --git a/games-engines/devilutionx/Manifest b/games-engines/devilutionx/Manifest
index cc8a8e0d7eadf..d134328735a74 100644
--- a/games-engines/devilutionx/Manifest
+++ b/games-engines/devilutionx/Manifest
@@ -1,2 +1 @@
-DIST devilutionx-1.5.4.tar.xz 22665424 BLAKE2B 2debdc0235618bf3b244da4b6ef48af45c0940bba7b923fefec3d1a2183e80459b5a997440008d56fe9483cb84e2b78c6eff41e21b4c25617fba067e7e27f704 SHA512 1d601453a826d4a214f851844c1b6e68114ac099f152464edbabe4e6bfd4553746ab1e6da83a01e6318e83f8e559000052a991fbfb7e88c6f1a7e9d059ab3380
 DIST devilutionx-1.5.5.tar.xz 22561696 BLAKE2B 2023d8483f712507a90b0a121ac985a0cbeb745989d501b8b8a9de8367d1645cdc58767d0992d579181710518b63177dbf591d97aea318a3fe12c9d9a587d8d5 SHA512 e62d11f9970625f5d20a0b9a46a2c90b6d837e02ca1d7665b0d8e21049d745237ed2b6f17c40e606178ae987a4e5a9a6d711844fef7c173c71c1192689697bb1
diff --git a/games-engines/devilutionx/devilutionx-1.5.4-r1.ebuild b/games-engines/devilutionx/devilutionx-1.5.4-r1.ebuild
deleted file mode 100644
index a885ff46e940a..0000000000000
--- a/games-engines/devilutionx/devilutionx-1.5.4-r1.ebuild
+++ /dev/null
@@ -1,89 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake xdg
-
-DESCRIPTION="Diablo engine for modern operating systems"
-HOMEPAGE="https://github.com/diasurgical/devilutionX/"
-SRC_URI="
-	https://github.com/diasurgical/devilutionX/releases/download/${PV}/devilutionx-src.tar.xz
-		-> ${P}.tar.xz
-"
-S=${WORKDIR}/${PN}-src-${PV}
-
-LICENSE="
-	Sustainable-Use-1.0
-	Boost-1.0 BSD CC-BY-4.0 GPL-2+ LGPL-2.1+ MIT OFL-1.1
-	zerotier? ( BUSL-1.1 )
-"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc64 ~x86"
-IUSE="debug +sodium test zerotier"
-RESTRICT="bindist mirror !test? ( test )"
-
-RDEPEND="
-	app-arch/bzip2:=
-	dev-libs/libfmt:=
-	media-libs/libsdl2[haptic,joystick,opengl,video]
-	media-libs/sdl2-image[png]
-	media-libs/sdl_audiolib
-	virtual/zlib:=
-	sodium? ( dev-libs/libsodium:= )
-"
-DEPEND="
-	${RDEPEND}
-	dev-cpp/simpleini
-	test? ( dev-cpp/gtest )
-"
-BDEPEND="
-	sys-devel/gettext
-"
-
-CMAKE_SKIP_TESTS=(
-	# timedemo tests only pass when game assets are available
-	Timedemo.
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	# ensure system copies are used
-	rm -r dist/{simpleini,sdl_audiolib}-src || die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_TESTING=$(usex test)
-		-DCCACHE_PROGRAM=no #813768
-		-DDEBUG=$(usex debug)
-		-DDISABLE_LTO=yes # let CFLAGS control this
-		-DDISABLE_ZERO_TIER=$(usex !zerotier)
-		-DPACKET_ENCRYPTION=$(usex sodium)
-		-DPIE=yes
-	)
-
-	cmake_src_configure
-}
-
-src_install() {
-	local DOCS=( Packaging/nix/README.txt docs/*.md )
-	cmake_src_install
-
-	rm -- "${ED}"/usr/share/diasurgical/devilutionx/README.txt || die
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if [[ ! ${REPLACING_VERSIONS} ]]; then
-		elog "In order to play the game, you will need to copy the following data file"
-		elog "from the original game, and optionally the hellfire expansion files:"
-		elog "	- DIABDAT.MPQ"
-		elog "	- hellfire.mpq hfmonk.mpq hfmusic.mpq hfvoice.mpq"
-		elog "to ~/.local/share/diasurgical/devilution/"
-		elog
-		elog "See ${EROOT}/usr/share/doc/${PF}/README.txt* for details."
-	fi
-}