diff --git a/dev-python/trio/Manifest b/dev-python/trio/Manifest
index 2ca651e4ed695..1f8f311e399ee 100644
--- a/dev-python/trio/Manifest
+++ b/dev-python/trio/Manifest
@@ -1 +1,2 @@
 DIST trio-0.33.0.gh.tar.gz 617029 BLAKE2B f30a3782329e8795bec327a3d4c495692e2b6c46ca4bcea4f6ea184a2f50efbf0ec7efa47dd9427d70a352eabfe34f28cdcf4237ebf157dd7bc43d34b916addc SHA512 9e92a233669bc98a2f394d6a06910fc602e5461f5c4aae384521ed23cac8c90097044aa3f2db32c787cd5b608701bf73a0a909fdccee54b535fb0e23b774e593
+DIST trio-0.34.0.gh.tar.gz 619212 BLAKE2B 21bace58d72520467391d1fd8c82706f8b57136e35ef8410bd3a52421510ecc6353893dd1fd88c063b28629aaec2d87f31f0a4f2954ec40471622bbde3bca75b SHA512 f38dca537326fbebd733844a4e49f91b3739cb9806b72e288441d54622d310e2663085b061ff21d47db6e2dc5196c9013921dbb5122d99b5c67354aea0592166
diff --git a/dev-python/trio/trio-0.34.0.ebuild b/dev-python/trio/trio-0.34.0.ebuild
new file mode 100644
index 0000000000000..a861feb059037
--- /dev/null
+++ b/dev-python/trio/trio-0.34.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..15} python3_{14,15}t )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+	https://github.com/python-trio/trio/
+	https://pypi.org/project/trio/
+"
+SRC_URI="
+	https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-23.2.0[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	>=dev-python/sniffio-1.3.0[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( "${PN}" )
+# xdist causes import errors
+distutils_enable_tests pytest
+# Bug https://bugs.gentoo.org/916756
+# distutils_enable_sphinx docs/source \
+# 	dev-python/immutables \
+# 	dev-python/sphinxcontrib-trio \
+# 	dev-python/sphinx-rtd-theme \
+# 	dev-python/towncrier
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Times out on slower arches (ia64 in this case)
+		# https://github.com/python-trio/trio/issues/1753
+		tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+		# requires ruff
+		_tests/tools/test_gen_exports.py
+	)
+
+	rm -rf trio || die
+	epytest -m "not redistributors_should_skip" --pyargs trio \
+		--skip-optional-imports
+}