app-office/texmaker: drop 6.0.0

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

app-office/texmaker/Manifest

@@ -1,2 +1 @@
-DIST texmaker-6.0.0.tar.bz2 14920994 BLAKE2B 7a41003f1e37219f41a48937f2eb3417ede4b59bd463d10df774892b89386b8b71fdbea788298d50eba74805a26d760fd6a90d19bec275fd05f3523d29a2c9b6 SHA512 173194510ce888297b6f6dc4e30bd0e8c1aa448d6ac1ea27b4f356fe36992bb8f4712a3ad03956f0952da72edd87e09695ea0eeb63fff43ff678a5dfa4f4ad7d
 DIST texmaker-6.0.1.tar.bz2 14932651 BLAKE2B cf19d88adce801de9a2409fb3e61cb20bbac0552d1c1d9816ac0362facec5e6b6e3ad115e6da6338ef4cb5e9a80c6e4b05610f587991601b9d20b5a827079a6d SHA512 466b661ffcafa5f5df852ab95afb848a6f2fb2cb47585d5ada0fee796c2a3096f13a64a41a3e82fe9cf4e96de90da52227283b1f2a195f28b36844609c02cb81

app-office/texmaker/texmaker-6.0.0.ebuild

@@ -1,86 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake optfeature xdg
-
-DESCRIPTION="Powerful LaTeX-IDE"
-HOMEPAGE="https://xm1math.net/texmaker/"
-SRC_URI="https://xm1math.net/texmaker/${P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64"
-IUSE="webengine"
-
-# dev-qt/qtbase slot op: Qt6::CorePrivate, includes private/qabstractitemmodel_p.h
-RDEPEND="
-	app-text/hunspell:=
-	app-text/texlive-core
-	dev-qt/qt5compat:6
-	dev-qt/qtbase:6=[concurrent,gui,network,widgets,xml]
-	dev-qt/qtdeclarative:6
-	virtual/latex-base
-	webengine? ( dev-qt/qtwebengine:6[widgets] )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	dev-qt/qttools:6[linguist]
-	virtual/pkgconfig
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-6.0.0-unbundle_hunspell_synctex.patch
-	"${FILESDIR}"/${PN}-6.0.0-unforce_webengine.patch
-	"${FILESDIR}"/${PN}-6.0.0-fix_lto_mismatch.patch
-)
-
-src_prepare() {
-	# -> app-text/hunspell
-	rm -r 3rdparty/hunspell || die
-	sed -e '/3rdparty\/hunspell/d' \
-		-i CMakeLists.txt || die
-
-	# -> app-text/texlive-core
-	rm -r 3rdparty/synctex || die
-	sed -e '/3rdparty\/synctex/d' \
-		-i CMakeLists.txt || die
-
-	# fix helpdir
-	sed -e "s:texmaker/usermanual_:doc/${PF}/html/usermanual_:" \
-		-e "s:texmaker/latexhelp.html:doc/${PF}/html/latexhelp.html:" \
-		-i src/texmaker.cpp || die
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DINTERNALBROWSER=$(usex webengine)
-	)
-
-	cmake_src_configure
-}
-
-src_install() {
-	local DOCS+=( datas/dictionaries/*README*.txt datas/CHANGELOG.txt AUTHORS )
-	local HTML_DOCS=( datas/doc/. )
-
-	cmake_src_install
-
-	# already installed in docdir
-	rm "${ED}"/usr/share/${PN}/{*.html,*.png,*.txt,AUTHORS,COPYING} || die
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "conversion tools and print support" app-text/ghostscript-gpl
-	optfeature "PostScript tools" app-text/psutils
-	optfeature "graphic tools" media-libs/netpbm
-	optfeature "integration of R code (Sweave)" dev-lang/R
-	optfeature "automation" dev-tex/latexmk
-	optfeature "XeLaTex engine" dev-texlive/texlive-xetex
-	optfeature "the vector graphics language (.asy)" media-gfx/asymptote
-}