From 2a47be89107c1a046ec3030712ce2d9b7a2adb87 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 2 Apr 2022 10:56:24 +0200
Subject: [PATCH] dev-python/pdm-pep517: Bump to 0.12.3
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pdm-pep517/Manifest                |  1 +
 .../pdm-pep517/pdm-pep517-0.12.3.ebuild       | 58 +++++++++++++++++++
 2 files changed, 59 insertions(+)
 create mode 100644 dev-python/pdm-pep517/pdm-pep517-0.12.3.ebuild

diff --git a/dev-python/pdm-pep517/Manifest b/dev-python/pdm-pep517/Manifest
index a9a4b5ba85e5d..299d0166e6216 100644
--- a/dev-python/pdm-pep517/Manifest
+++ b/dev-python/pdm-pep517/Manifest
@@ -1 +1,2 @@
 DIST pdm-pep517-0.12.1.gh.tar.gz 303954 BLAKE2B 65344c2571264b9fadcffcf5ae05f42246912dce3e7029a1ea5e91df72f1c9425d603024099146cb7d9ed95d8e3ab0fcf5058ab35346893e28d3595d430548f6 SHA512 a7c27c685eec274798b5d9fa7fd3d7ec7ca77d204110c7c9962a53b1522c4c6dbc56d7413ce5ff6fe8e8f091b0d4e4914b9e3296dc226bcae9f5fbc2cb28444e
+DIST pdm-pep517-0.12.3.gh.tar.gz 304242 BLAKE2B ad4beb6ab35c219e1991b585bf9ce087be3e7e957f34b1dbc9de676f7b49c3084471e2b55c634eb6fd1cf6cb88dd4161b5060a17a5ca7e5e3ae57c9610303f6e SHA512 4c0f098d5237353fea73ef62149b8177987881239cb6b1b112bd6789931acd7484c56d413f780db4f23c60f4ff3a37c6956de3e1de472fed114487925b0e3553
diff --git a/dev-python/pdm-pep517/pdm-pep517-0.12.3.ebuild b/dev-python/pdm-pep517/pdm-pep517-0.12.3.ebuild
new file mode 100644
index 0000000000000..c95abf912f725
--- /dev/null
+++ b/dev-python/pdm-pep517/pdm-pep517-0.12.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-pep517/
+	https://github.com/pdm-project/pdm-pep517/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-pep517/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/cerberus-1.3.4[${PYTHON_USEDEP}]
+	dev-python/license-expression[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r pdm/pep517/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.pep517\._vendor\.:from :' \
+		-e 's:from pdm\.pep517\._vendor ::' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}