media-libs/libva: Version bump to 2.23.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

media-libs/libva/Manifest

@@ -1 +1,2 @@
 DIST libva-2.22.0.tar.gz 301705 BLAKE2B b438c95613628b8eb1150238016bafdf2ef33fc01ed78742cd50768238cedf5475752a6dd7413ee217961a705abcd7628219ddf3f13c5aa77015b6bbb4e77929 SHA512 cd633e5e09eac1ed10f1fc12b0f664f836e0eda9e47c17e1295b746cfd643a18fd0564a06a148ced3cf1e2321aa4d21275918bcf8c717d3981e98a598179f370
+DIST libva-2.23.0.tar.gz 304617 BLAKE2B 905a389466b4213c644a01823220b9725649fc7807222707f003f17909f58c5957376677ba3e9758078246a4219d31348f7fec3b0bce6ee58021a0959b09d0c0 SHA512 03e3648b43a0c82c7840203d0b6286879317667ad9d4cf8d7813a29023ffebaf6cd5719a1a9f5fb0f2671738bd675c69a08fd27aa73b7339c8524a8f794150bc

media-libs/libva/libva-2.23.0.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib optfeature
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="https://github.com/intel/libva"
+
+if [[ ${PV} = *9999 ]] ; then
+	inherit git-r3
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="https://github.com/intel/libva"
+else
+	SRC_URI="https://github.com/intel/libva/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1)"
+IUSE="glx wayland X"
+REQUIRED_USE="glx? ( X )"
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.75[${MULTILIB_USEDEP}]
+	wayland? (
+		>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
+	)
+	X? (
+		glx? (
+			media-libs/libglvnd[X?,${MULTILIB_USEDEP}]
+		)
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
+		x11-libs/libxcb:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )
+"
+BDEPEND="
+	wayland? ( dev-util/wayland-scanner )
+	virtual/pkgconfig
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/va/va_backend_glx.h
+	/usr/include/va/va_x11.h
+	/usr/include/va/va_dri2.h
+	/usr/include/va/va_dricommon.h
+	/usr/include/va/va_glx.h
+)
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddriverdir="${EPREFIX}/usr/$(get_libdir)/va/drivers"
+		-Ddisable_drm=false
+		-Dwith_x11=$(usex X)
+		-Dwith_glx=$(usex X $(usex glx))
+		-Dwith_wayland=$(usex wayland)
+		-Denable_docs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	optfeature_header
+	optfeature "Older Intel GPU support up to Gen8" media-libs/libva-intel-driver
+	optfeature "Newer Intel GPU support from Gen9+" media-libs/libva-intel-media-driver
+}