dev-java/openjdk-jre-bin: add 17.0.20_p8

Bug: https://bugs.gentoo.org/979647
Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/1585
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-java/openjdk-jre-bin/Manifest

@@ -1,5 +1,6 @@
 DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.31_11.tar.gz 43519453 BLAKE2B 3489ebe93c97a746b90ff2a913013ca026b21a4d582bf09ed20558f6c4741534a9a9fbd59f8762d08e01c35ee57aba63c6d2e8887198f00f30b396a77c480127 SHA512 071de48cc48c9cba3120c65f34dded9b0c07626ccecda71687434ec9ba315f60bd85a60623125e11620349076514ab5d3f16a872cf4823cfb0896263c9df75fb
 DIST OpenJDK17U-jre_x64_linux_hotspot_17.0.19_10.tar.gz 46671975 BLAKE2B 5fbd9f3bb7c32cec3a4102d352e242da2cb2094912025fd1cdfe9fb827839e2cb31df0b0149b7c233eb7cb6754d7d39dfd4e8c77f8b447259210acc5155f393d SHA512 eca00a8d2fb1b48cfb431705f04ed977c74fcd2c901067efe19318ff28c92a452712d2b89a923ca357f8a2276f504c540895aa2ae4993403e6892ff9d699e294
+DIST OpenJDK17U-jre_x64_linux_hotspot_17.0.20_8.tar.gz 46642500 BLAKE2B b7e72dbb37985b5aab1e6711328e49734a62730c9fae9758088cec64bbd2e8b5ac86c8ffaebca9707f295f820d197075f80fad0cd7903eebb849d5cb985aed29 SHA512 b757703019ba75b1805a88eff2352a3b869b6e0c7f4383592fe2e9c9037b866bf67855d017c46c1bdde6787f210060c8ee1279d1f63c6213b6baba7f4b38bd7d
 DIST OpenJDK21U-jre_x64_linux_hotspot_21.0.11_10.tar.gz 52099793 BLAKE2B 553e6a3267a8a65aa967f87f15bbeecf094a3b9b4cb7b9be1cdc1f8978b8d06cf2f30b754aa13edccb941db56bc102668a6aa756120b3e23c630e42bb228ce31 SHA512 14cb17e27c528338eb0d2ea685abaf5038a42442b1f9d61bb10b0a8761c3c9a06356f775812e2ce093f89108281e2f33461e2835bfcf314e04d2941fd09b38a2
 DIST OpenJDK21U-jre_x64_linux_hotspot_21.0.12_8.tar.gz 52069757 BLAKE2B 07f3fbfb8fd469874bfe22d6dcb52f50705ed9b36ccb6a038d2037f8f17356e51978c32dc537e6995d811947baf2d3e528a8917aa76bffe79f84a78a5432f654 SHA512 f96eeb2cfe6d104288cc986bd9f9b641791aa438c91629fad91c4c33f9b49232c47a35612afaa8a4eb1214c7bac21f82f27cf97f019e245ba34358f5c47d4b2e
 DIST OpenJDK25U-jre_x64_linux_hotspot_25.0.3_9.tar.gz 61687836 BLAKE2B ef3616cb4b1febc4f319be9144228f524a4d52074dfef431ec5f631b9c652a7e60cca731681ab615bf42a01daee37f28987283418a7a56acda3f72b02d447c96 SHA512 ea28bce0f082f7943236fc4b9e5bd8c6fd3c0c4b4204d8a8c782680565bbeb348db33cc50a93d4e744b8cc2c0e49016e90776ae735b16b1a1bbbf1571ae5e67c

dev-java/openjdk-jre-bin/openjdk-jre-bin-17.0.20_p8.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/adoptium/temurin${SLOT}-binaries/releases/download/jdk-${MY_PV}/OpenJDK${SLOT}U-jre_${1}_linux_hotspot_${MY_PV//+/_}.tar.gz
+		)"
+}
+
+MY_PV=${PV/_p/+}
+SLOT=${MY_PV%%[.+]*}
+
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by Eclipse Temurin"
+HOMEPAGE="https://adoptium.net/"
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+IUSE="alsa cups headless-awt selinux"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	virtual/zlib:=
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk-${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${PN}-${SLOT}"
+	local ddest="${ED}/${dest#/}"
+
+	# https://bugs.gentoo.org/922741
+	docompress "${dest}/man"
+
+	# Not sure why they bundle this as it's commonly available and they
+	# only do so on x86_64. It's needed by libfontmanager.so. IcedTea
+	# also has an explicit dependency while Oracle seemingly dlopens it.
+	rm -vf lib/libfreetype.so || die
+
+	# Oracle and IcedTea have libjsoundalsa.so depending on
+	# libasound.so.2 but AdoptOpenJDK only has libjsound.so. Weird.
+	if ! use alsa ; then
+		rm -v lib/libjsound.* || die
+	fi
+
+	if use headless-awt ; then
+		rm -v lib/lib*{[jx]awt,splashscreen}* || die
+	fi
+
+	rm -v lib/security/cacerts || die
+	dosym -r /etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	java-vm_install-env "${FILESDIR}"/${PN}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+	java-vm-2_pkg_postinst
+}