mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-06 02:17:34 -08:00
dev-util/geany-plugins: version bump to 1.30.
This commit also simplifies LINGUAS handling. Package-Manager: Portage-2.3.4, Repoman-2.3.2 Closes: https://github.com/gentoo/gentoo/pull/3584
This commit is contained in:
Chris Mayo
Patrice Clement
parent
795f3a90c8
commit
257dd728f8
@ -1 +1,2 @@
|
||||
DIST geany-plugins-1.28.tar.gz 4453038 SHA256 918f644053ea205fdf0f2185ac3b8e21339764e0e761a38583f2dda7de7fdb97 SHA512 027fc5923d405a8246786e48e0d36c5da8f580b9f18510933063cc4c452ee5aaa68af4568ee20d640c1dd2bcb29a9361b8558a81a5a83f46b5d99c9ff639306d WHIRLPOOL a328557ccd899ce56ba2cb12875836ecbf5939492a1e19a61e5e2db15a5b10969e1cbf0eb912d551c75e9fa7c49e65fa8a48f7e2e2ebfd4477b4c88b4e6857ea
|
||||
DIST geany-plugins-1.30.tar.gz 4469990 SHA256 a49202d1c6b2a82446a79c57854596de1e231481163f680c7654f2cb165bc249 SHA512 11dc44215aaa369831c249ef84b5dd0ee7eecdfbbf4707fc6165d78201e9e755447463c171ac6c8b2bc70df28a97b23762073ab9b31f7c33285d4728089da807 WHIRLPOOL ada9c5cd3f78948384c9add373d8b60aa09c0de931304aae4b41f54aaa35dab3450e946e2b39d84c069521113a55720350170edc03253960854a0b842e31903e
|
||||
|
||||
144
dev-util/geany-plugins/geany-plugins-1.30.ebuild
Normal file
144
dev-util/geany-plugins/geany-plugins-1.30.ebuild
Normal file
@ -0,0 +1,144 @@
|
||||
# Copyright 1999-2017 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
PYTHON_COMPAT=( python2_7 )
|
||||
|
||||
inherit eutils python-single-r1 vala
|
||||
|
||||
DESCRIPTION="A collection of different plugins for Geany"
|
||||
HOMEPAGE="https://plugins.geany.org"
|
||||
SRC_URI="https://plugins.geany.org/${PN}/${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
|
||||
|
||||
IUSE="gtk3 +autoclose +automark +commander ctags debugger +defineformat enchant git gpg gtkspell lua multiterm nls +overview python scope soup"
|
||||
REQUIRED_USE="
|
||||
gtk3? ( !debugger !multiterm !python !scope )
|
||||
python? ( ${PYTHON_REQUIRED_USE} )
|
||||
"
|
||||
|
||||
GTK_COMMON_DEPEND="
|
||||
gtk3? ( x11-libs/gtk+:3 )
|
||||
!gtk3? ( x11-libs/gtk+:2 )
|
||||
"
|
||||
COMMON_DEPEND="
|
||||
>=dev-util/geany-1.26[gtk3=]
|
||||
dev-libs/glib:2
|
||||
dev-libs/libxml2:2
|
||||
autoclose? ( ${GTK_COMMON_DEPEND} )
|
||||
commander? ( ${GTK_COMMON_DEPEND} )
|
||||
ctags? ( dev-util/ctags )
|
||||
debugger? ( x11-libs/vte:0 )
|
||||
defineformat? ( ${GTK_COMMON_DEPEND} )
|
||||
enchant? ( app-text/enchant )
|
||||
git? ( dev-libs/libgit2:= )
|
||||
gpg? ( app-crypt/gpgme:1= )
|
||||
gtkspell? (
|
||||
gtk3? ( app-text/gtkspell:3= )
|
||||
!gtk3? ( app-text/gtkspell:2 )
|
||||
)
|
||||
lua? ( dev-lang/lua:0= )
|
||||
multiterm? (
|
||||
$(vala_depend)
|
||||
x11-libs/gtk+:2
|
||||
>=x11-libs/vte-0.28:0
|
||||
)
|
||||
python? (
|
||||
dev-python/pygtk[${PYTHON_USEDEP}]
|
||||
${PYTHON_DEPS}
|
||||
)
|
||||
scope? ( x11-libs/vte:0 )
|
||||
soup? ( net-libs/libsoup:2.4 )
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
scope? ( sys-devel/gdb )
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
nls? ( sys-devel/gettext )
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
pkg_setup() {
|
||||
use python && python-single-r1_pkg_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
# bundled lib buster
|
||||
rm markdown/peg-markdown/markdown_lib.c || die
|
||||
# devhelp plugin bundles devhelp
|
||||
|
||||
default
|
||||
|
||||
use multiterm && vala_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local myeconfargs=(
|
||||
--disable-cppcheck
|
||||
--disable-extra-c-warnings
|
||||
$(use_enable !gtk3 geanydoc)
|
||||
# GeanyGenDoc requires ctpl which isn’t yet in portage
|
||||
--disable-geanygendoc
|
||||
# peg-markdown is bundled, use app-text/discount instead
|
||||
--disable-peg-markdown
|
||||
--enable-addons
|
||||
--enable-codenav
|
||||
--enable-geanyextrasel
|
||||
--enable-geanyinsertnum
|
||||
--enable-geanylatex
|
||||
--enable-geanymacro
|
||||
--enable-geanynumberedbookmarks
|
||||
--enable-geanyprj
|
||||
--enable-geanyvc
|
||||
--enable-lineoperations
|
||||
--enable-lipsum
|
||||
--enable-pairtaghighlighter
|
||||
--enable-pohelper
|
||||
--enable-pretty-printer
|
||||
--enable-projectorganizer
|
||||
--enable-sendmail
|
||||
--enable-shiftcolumn
|
||||
--enable-tableconvert
|
||||
--enable-treebrowser
|
||||
--enable-xmlsnippets
|
||||
$(use_enable autoclose)
|
||||
$(use_enable automark)
|
||||
$(use_enable commander)
|
||||
$(use_enable ctags geanyctags)
|
||||
$(use_enable debugger)
|
||||
$(use_enable defineformat)
|
||||
$(use_enable enchant spellcheck)
|
||||
$(use_enable git gitchangebar)
|
||||
$(use_enable gpg geanypg)
|
||||
$(use_enable gtkspell)
|
||||
$(use_enable multiterm)
|
||||
$(use_enable lua geanylua)
|
||||
$(use_enable nls)
|
||||
$(use_enable overview)
|
||||
$(use_enable python geanypy)
|
||||
$(use_enable scope)
|
||||
# Having updatechecker… when you’re using a package manager?
|
||||
$(use_enable soup updatechecker)
|
||||
$(use_enable soup geniuspaste)
|
||||
# Relies on obsolete and vulnerable webkit-gtk versions
|
||||
--disable-devhelp
|
||||
--disable-markdown
|
||||
--disable-webhelper
|
||||
)
|
||||
|
||||
econf "${myeconfargs[@]}"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
|
||||
prune_libtool_files --modules
|
||||
|
||||
# make installs all translations if LINGUAS is empty
|
||||
if [[ -n "${LINGUAS+x}" && -z "$LINGUAS" ]]; then
|
||||
rm -r "${D}/usr/share/locale/" || die
|
||||
fi
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user