diff --git a/sys-power/libacpica/Manifest b/sys-power/libacpica/Manifest
index 2244e967b0042..b045b59c78370 100644
--- a/sys-power/libacpica/Manifest
+++ b/sys-power/libacpica/Manifest
@@ -1 +1,2 @@
 DIST libacpica-debian-0_20220331-6.tar.bz2 450164 BLAKE2B 85c5263d13074059f9a0f541d70d5d81a725b10de343567196f7bbcb9985d847e2d93eede2388efd8b83b76d2e37f91461a0bee0c37e1f0a4502d6ad71ea7ba1 SHA512 c9b298d096a4839ffc2167be3b7c0528b4d5dacbdb6a0efd81346144c8b00b979113abe72517b673db2835d0f5f24b10a4e19e17adb503784215c7d05443b3ea
+DIST libacpica-debian-0_20220331-7.tar.bz2 450211 BLAKE2B 777ddbbc64b4ca49e0b3b9227f7cf2eb0a628079ec4d96275f5bb4abc6709acd981c3103760a451a4be176ca9472d310f97f3efc89f0dcc67ad5998ea9a8fa80 SHA512 7bcc10737ef01b0dd36868b5da60cf69cba042f6f243cc8723df1288f618eb9650eb0f46717c5c83aa106e7e907fb038e54a7131bbdb144143e6f635339c74f4
diff --git a/sys-power/libacpica/libacpica-0_pre20220331_p7.ebuild b/sys-power/libacpica/libacpica-0_pre20220331_p7.ebuild
new file mode 100644
index 0000000000000..7369444c003d3
--- /dev/null
+++ b/sys-power/libacpica/libacpica-0_pre20220331_p7.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="ACPICA as a library"
+HOMEPAGE="https://salsa.debian.org/hurd-team/libacpica"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://salsa.debian.org/hurd-team/libacpica.git"
+	inherit git-r3
+elif [[ ${PV} == *_pre*_p* ]] ; then
+	# These are proper Debian relaeses. libacpica isn't currently
+	# part of the Debian archive, so this is the best we can do (no
+	# 'orig' tarballs).
+	LIBACPICA_PV=0_$(ver_cut 3)-$(ver_cut 5)
+
+	SRC_URI="https://salsa.debian.org/hurd-team/libacpica/-/archive/debian/${LIBACPICA_PV}/libacpica-debian-${LIBACPICA_PV}.tar.bz2"
+	S="${WORKDIR}"/${PN}-debian-${LIBACPICA_PV}
+else
+	# Snapshots
+	LIBACPICA_COMMIT="0c3593e27947ef0734a070143caadaed28438354"
+	SRC_URI="https://salsa.debian.org/hurd-team/libacpica/-/archive/${LIBACPICA_COMMIT}/libacpica-${LIBACPICA_COMMIT}.tar.bz2"
+fi
+
+LICENSE="BSD GPL-2+"
+SLOT="0"
+if [[ ${PV} != *9999* ]] ; then
+	KEYWORDS="~amd64 ~x86"
+fi
+
+RDEPEND="
+	x11-libs/libpciaccess
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	eapply $(sed -e 's:^:debian/patches/:' debian/patches/series || die)
+
+	sed -i -e 's:ar crs:$(AR) crs:' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC
+}
+
+src_compile() {
+	emake PREFIX="${EPREFIX}"/usr
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr libdir="${EPREFIX}/usr/$(get_libdir)" install
+}