diff --git a/dev-python/librt/Manifest b/dev-python/librt/Manifest
new file mode 100644
index 0000000000000..33e1de66f36f4
--- /dev/null
+++ b/dev-python/librt/Manifest
@@ -0,0 +1 @@
+DIST librt-0.6.2.gh.tar.gz 82045 BLAKE2B 7dd42e06c4bfa77961a73d495bebf94b2046f84299360fdc93ddb9aea0ea50024c7ebf56e369155e1de98556f169a13179d83480d3a939bde362e4a103e39059 SHA512 8b36eab38aaeeffdd2f520a58df66c993efbf7a39dfa7c4c76d440e0d987fbd19b16241acddcac335867ade1f9320385aa01ed957859bd5f7de04ecfd8ffe2a5
diff --git a/dev-python/librt/librt-0.6.2.ebuild b/dev-python/librt/librt-0.6.2.ebuild
new file mode 100644
index 0000000000000..6d5f414ac89fc
--- /dev/null
+++ b/dev-python/librt/librt-0.6.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Mypyc runtime library"
+HOMEPAGE="
+	https://github.com/mypyc/librt/
+	https://pypi.org/project/librt/
+"
+# no tests: https://github.com/mypyc/librt/issues/17
+SRC_URI="
+	https://github.com/mypyc/librt/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT PSF-2.4"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	test? (
+		dev-python/mypy-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# this package is a mess
+	# https://github.com/mypyc/librt/issues/17
+	mv lib-rt/* . || die
+}
+
+python_test() {
+	rm -rf librt || die
+	epytest smoke_tests.py
+}
diff --git a/dev-python/librt/metadata.xml b/dev-python/librt/metadata.xml
new file mode 100644
index 0000000000000..bd5eb9d3c6ea4
--- /dev/null
+++ b/dev-python/librt/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">mypyc/librt</remote-id>
+		<remote-id type="pypi">librt</remote-id>
+	</upstream>
+</pkgmetadata>