app-backup/dar: add 2.7.18

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

app-backup/dar/Manifest

@@ -1,2 +1,3 @@
 DIST dar-2.7.16.tar.gz 2444321 BLAKE2B 019f441fe5ca951fbb43b661cbc9d6c5c1992e825005fb434579b2dedb6dc379593ffa11a1ee651da6047c16b8264a19dbbbc7e98bb2d20790890058f245a03c SHA512 bc70aecc05641314144c9a252fec1d256b3a19e38837ee2bb1320bfc7b659bc1e7399e6e1377862e25d25c798fdf90e535794d8ba68f0b9754d9e6bfb9cb50fe
 DIST dar-2.7.17.tar.gz 2444942 BLAKE2B 62f99e75d3657a70f24513aafb9681ab235269931ba4eb5d893440746b393c8ac59938d5643ce50e4dd8d37a6672e7d6760cb67348239271dcfb4404abd862bd SHA512 99501e31e1c438ef4406e6bccc190b39b4313e2074adfb02e3f205d225f2292a58aded631e5df3320a11f6313106cf8128f522f3975d8a53eb1a5a6971d946ff
+DIST dar-2.7.18.tar.gz 2449032 BLAKE2B 515c82b08739e2c44d906fbbd4bb0c637f5c4c5d432131e57ee22b1418291561ff8a3d9b73c903466e4d1d25f928416ef03db355ca2550197247c6b4ffd999b9 SHA512 ddcb4988dba7f83455d41c1f2aa70ba6975df2c89b3ed1328b48c114bd542ed056b7477aea8cabf56c34e6131e570a1a843e7395ec4dec2cb14f61897bbc618f

app-backup/dar/dar-2.7.18.ebuild

@@ -0,0 +1,97 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+DESCRIPTION="A full featured backup tool, aimed for disks"
+HOMEPAGE="http://dar.linux.free.fr/"
+SRC_URI="https://downloads.sourceforge.net/project/dar/dar/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux"
+IUSE="argon2 curl dar32 dar64 doc gcrypt gpg lz4 lzo nls rsync xattr"
+
+REQUIRED_USE="
+	?? ( dar32 dar64 )
+	gpg? ( gcrypt )
+"
+
+RESTRICT="test" # need to be run as root
+
+RDEPEND="
+	app-arch/bzip2:=
+	app-arch/xz-utils
+	app-arch/zstd:=
+	dev-libs/libthreadar
+	sys-libs/libcap
+	>=sys-libs/zlib-1.2.3:=
+	argon2? ( app-crypt/argon2:= )
+	curl? ( net-misc/curl )
+	gcrypt? (
+		dev-libs/libgcrypt:0=
+		dev-libs/libgpg-error
+	)
+	gpg? (
+		app-crypt/gpgme:=
+		dev-libs/libassuan:=
+	)
+	lz4? ( app-arch/lz4:= )
+	lzo? ( dev-libs/lzo:2 )
+	nls? ( virtual/libintl )
+	rsync? ( net-libs/librsync:= )
+	xattr? ( sys-apps/attr )
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	doc? ( app-text/doxygen )
+	nls? ( sys-devel/gettext )
+"
+
+QA_PKGCONFIG_VERSION=""	# Bug #862025 - upstream has a different numbering scheme for libdar
+
+src_configure() {
+	# configure.ac is totally funked up regarding the AC_ARG_ENABLE
+	# logic.
+	# For example "--enable-dar-static" causes configure to DISABLE
+	# static builds of dar.
+	# Do _not_ use $(use_enable) until you have verified that the
+	# logic has been fixed by upstream.
+	local myconf=(
+		--disable-dar-static
+		--disable-python-binding
+		--disable-upx
+		$(usev !argon2 --disable-libargon2-linking)
+		$(usev !curl --disable-libcurl-linking)
+		$(usev dar32 --enable-mode=32)
+		$(usev dar64 --enable-mode=64)
+		$(usev !doc --disable-build-html)
+		$(usev !gcrypt --disable-libgcrypt-linking)
+		$(usev !gpg --disable-gpgme-linking)
+		$(usev !lz4 --disable-liblz4-linking)
+		$(usev !lzo --disable-liblzo2-linking)
+		$(usev !nls --disable-nls)
+		$(usev !rsync --disable-librsync-linking)
+		$(usev !xattr --disable-ea-support)
+	)
+
+	# Bug 103741
+	filter-flags -fomit-frame-pointer
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
+
+	einstalldocs
+
+	find "${ED}" -name "*.la" -delete || die
+
+	# Bug 729150
+	rm "${ED}/usr/share/doc/${PF}/html/samples/MyBackup.sh.tar.gz" || die
+}