diff --git a/app-crypt/xca/xca-2.9.0-r1.ebuild b/app-crypt/xca/xca-2.9.0-r1.ebuild
new file mode 100644
index 0000000000000..83c0e44f35fa1
--- /dev/null
+++ b/app-crypt/xca/xca-2.9.0-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+inherit cmake virtualx xdg-utils
+
+DESCRIPTION="A GUI to OpenSSL, RSA public keys, certificates, signing requests etc"
+HOMEPAGE="https://hohnstaedt.de/xca/"
+SRC_URI="https://github.com/chris2511/xca/archive/refs/tags/RELEASE.${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/xca-RELEASE.${PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="doc"
+
+RDEPEND="
+	dev-libs/libltdl:0=
+	dev-qt/qtbase:6[sqlite,widgets]
+	dev-qt/qttools:6[assistant]
+	dev-libs/openssl:*
+	doc? ( app-text/linuxdoc-tools )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+	doc? ( dev-python/sphinx dev-python/sphinxcontrib-htmlhelp dev-python/sphinxcontrib-qthelp )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.8.0-man-page.patch"
+)
+
+src_configure() {
+	if ! use doc; then
+		xca_docs=-DSPHINX=
+	fi
+
+	local mycmakeargs=(
+		-DQTFIXEDVERSION=Qt6
+		$xca_docs
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	virtx default
+}
+
+src_install() {
+	cmake_src_install
+
+	insinto /etc/xca
+	doins misc/*.txt
+
+	dosym xca /usr/bin/xca-console
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}