From 2300c4055f87c7eb4e93fd4d7088d73639b2e7b3 Mon Sep 17 00:00:00 2001
From: Michael Mair-Keimberger <mm1ke@gentoo.org>
Date: Sun, 13 Jul 2025 20:50:49 +0200
Subject: [PATCH] gui-apps/wayvnc: revision bump for gbm fix

Signed-off-by: Michael Mair-Keimberger <mm1ke@gentoo.org>
Part-of: https://github.com/gentoo/gentoo/pull/42990
Signed-off-by: Michael Mair-Keimberger <mm1ke@gentoo.org>
---
 gui-apps/wayvnc/wayvnc-0.9.1-r1.ebuild | 55 ++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 gui-apps/wayvnc/wayvnc-0.9.1-r1.ebuild

diff --git a/gui-apps/wayvnc/wayvnc-0.9.1-r1.ebuild b/gui-apps/wayvnc/wayvnc-0.9.1-r1.ebuild
new file mode 100644
index 0000000000000..82f7aeab4f5bf
--- /dev/null
+++ b/gui-apps/wayvnc/wayvnc-0.9.1-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2019-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="VNC server for wlroots based Wayland compositors"
+HOMEPAGE="https://github.com/any1/wayvnc"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/any1/wayvnc.git"
+else
+	SRC_URI="https://github.com/any1/wayvnc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~riscv ~x86"
+fi
+
+LICENSE="ISC"
+SLOT="0"
+IUSE="gbm pam test tracing"
+
+RDEPEND="
+	=dev-libs/aml-0.3*
+	dev-libs/jansson:=
+	dev-libs/wayland
+	=gui-libs/neatvnc-0.9*[gbm?]
+	media-libs/mesa[egl(+),gles2(+),gbm(+)?]
+	x11-libs/libdrm
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	pam? ( sys-libs/pam )
+	tracing? ( dev-debug/systemtap )
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/wayland-protocols
+"
+BDEPEND="
+	app-text/scdoc
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature pam)
+		$(meson_feature gbm screencopy-dmabuf)
+		$(meson_use tracing systemtap)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}