sci-libs/cartopy: add 0.25.0

Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>

sci-libs/cartopy/Manifest

@@ -1 +1,2 @@
 DIST cartopy-0.24.1.gh.tar.gz 10701425 BLAKE2B b1c6980e4e2b03e6ca2f55eec949b7dc4f58577af3795f71af81bd25f0d6e6a2ef3aca1d09b73dbf9c8e9a611f697843189e60bd821516f80bdbc2af2a4f93af SHA512 de5a4c191e3917941b0bab4e9c92fb60a91ef0263f7066753fd64286c347304ae8b7529b08fa901669173e8630c2b396775daf98161e8cadc62346641555c01a
+DIST cartopy-0.25.0.gh.tar.gz 10716161 BLAKE2B b1240d6ae67427e4f9cbde2d7111350ca8f021b19f07bb7202f74e798a93512fe622a7522f39832752fc396a4aad84c6a815cb2be61d0b90225b58c18fd98bd5 SHA512 05916302e39edf13c89c5ef82db7b66ad29853cc905a14de74c0b5d06523a449be91e1ee9fe5a41e02ece793c7b22807386d1e794cb7e6cd50da8918bf2a7226

sci-libs/cartopy/cartopy-0.25.0.ebuild

@@ -0,0 +1,89 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{11..13} )
+
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 multiprocessing virtualx
+
+MY_PV=${PV/_beta/b}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Python package for geospatial data processing and analysis"
+HOMEPAGE="https://scitools.org.uk/cartopy"
+SRC_URI="https://github.com/SciTools/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	|| (
+		$(python_gen_cond_dep '
+			sci-libs/gdal[python,${PYTHON_USEDEP}]
+		')
+		sci-libs/gdal[python,${PYTHON_SINGLE_USEDEP}]
+	)
+	$(python_gen_cond_dep '
+		>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/pillow[jpeg,${PYTHON_USEDEP}]
+		dev-python/pyproj[${PYTHON_USEDEP}]
+		sci-libs/pyshp[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/setuptools-scm[${PYTHON_USEDEP}]
+		dev-python/cython[${PYTHON_USEDEP}]
+	')
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/filelock[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/flufl-lock[${PYTHON_USEDEP}]
+			dev-python/pytest-mpl[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Require network access, not covered by markers
+	lib/cartopy/tests/mpl/test_crs.py
+	lib/cartopy/tests/mpl/test_gridliner.py
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+	# Prepare matplotlib backend for test suite
+	export MPLCONFIGDIR="${T}"
+	echo "backend : Agg" > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	sed -i -e "s/exclude =/#exclude =/" pyproject.toml || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+
+	# Drop all tests needing network access
+	virtx epytest -n "$(makeopts_jobs)" -m "not network and not natural_earth" || die "test failed"
+}