mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-06 02:17:34 -08:00
net-misc/teamviewer: add 15.67.4
Signed-off-by: Martin Dummer <martin.dummer@gmx.net> Part-of: https://github.com/gentoo/gentoo/pull/43189 Closes: https://github.com/gentoo/gentoo/pull/43189 Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Martin Dummer
Sam James
parent
e174752a7b
commit
2021ec2da7
@ -2,3 +2,7 @@ DIST teamviewer_15.64.3_amd64.tar.xz 105993876 BLAKE2B e31eb3987f30db53ae068e662
|
||||
DIST teamviewer_15.64.3_arm64.tar.xz 105556100 BLAKE2B 97d6eb6736b275060cc34fcdd1602bb5561eae3922613b953ce29894916bfbf33ea94e50798f02f2da6caeb109ca8e9d373738f037f8236788139b351b1343c0 SHA512 a136d740b9c9452156c1d9cbf0df8a7b6ca26360d50a55584f233d3c8c929d269c6eb67edd89074972307e0f57315c9ac9480d6cd9113451d0751e388f934466
|
||||
DIST teamviewer_15.64.3_armhf.tar.xz 91335120 BLAKE2B c2e6b1fab27969d2a3fdbf1304be9f701682c742a1da94351867c2a044eeb5b744ac580379cdd79e85e328139c0ae16c6dde49d19e983f9544c7b69be8418234 SHA512 7dfb43a0d0852213587a4bbfea236e4d81ef0ebb969b4ab800b58ba87c1f9202b56124d0d74f158aa76aa453d51312d30f1fdb3cfc8737b4071fd51bd8c162a3
|
||||
DIST teamviewer_15.64.3_i386.tar.xz 108042200 BLAKE2B 5ef61f29f7c247b9db4f2a76300321ad3213d22b4a1aabf085c17386b3cdf257030d8d42c091c35c1083e18a567abeb1380b969ebfa82b4c9f944359551bca28 SHA512 af5dff943e2b8d140f7ffc373e77080ec00d780a99460ac37eb082aa0920a72feb67125def714f159391a5890684ba879880d58d525235e6314f8536055f230b
|
||||
DIST teamviewer_15.67.4_amd64.tar.xz 110691736 BLAKE2B 97f17063826c2f1e62664f30e78b2eb6784eacc53cb8aa48d4ae920e621eb622a44e22684950e77c20e9c8158dd9e22b3c999691fe244cf5d60e1017b2577f71 SHA512 94fece269d759ece0cbf57db3fc5e9585417dba72dd738ad1b3c7c3763a887f095cae1604a92926f63d0b7cdf76410252fc2c6b97a860ab3c35f3f42495989fe
|
||||
DIST teamviewer_15.67.4_arm64.tar.xz 110231804 BLAKE2B def572043f14a39af9cc9f13c28d4a11f0609fa19e43107c84a541150aa10e5984ddd4c3baecaefa13a946d4e8aaae48ad50182edc9e32ecfb6a094f6694fdea SHA512 3902aefee525dfc5bfa4f981fa1b0fb7775246f244e900902c02272d8a97a4de34dcaa3fdff6cf4e10f95cbc47efa5db0406a6f4b4b9164e2dd6f4247bb4e6af
|
||||
DIST teamviewer_15.67.4_armhf.tar.xz 96098424 BLAKE2B 38423563063eaaf9950a9949d0422bc7fdec244f4254002058fe60ac2a574d4dac36404b7de65b074c871250e7ea5c757ef654c7a3662657dd15920eeb9a2599 SHA512 8da8b8a420ce8fc13a62ee343d4c4f74f80c1e729c901f4ae390aa26a5dd6f7f918f1b3103bf076df64b74b3441a08be9e59b158b918d734ebd0274351f2c7a9
|
||||
DIST teamviewer_15.67.4_i386.tar.xz 112768816 BLAKE2B 1fb580e26258bb405e9c9d9e7fdc4f436a948ad0033fae3c72c03302225bd0eab272b9140f1e4e6a5d374802c3ebe8cec5722de312e02ce857fe8ee1beddd5ac SHA512 6d5d1a31b3e97205fb849d0c084bc39faa9d83ffa9c117f5268b68934ed822aabd1d2f53b49c095b452c184c5109dd1dcd14732ff2937b30bca3ab12b0463dfe
|
||||
|
||||
153
net-misc/teamviewer/teamviewer-15.67.4.ebuild
Normal file
153
net-misc/teamviewer/teamviewer-15.67.4.ebuild
Normal file
@ -0,0 +1,153 @@
|
||||
# Copyright 2021-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit desktop optfeature systemd xdg
|
||||
|
||||
MY_MAJOR="$(ver_cut 1)"
|
||||
MY_P="${PN}${MY_MAJOR}"
|
||||
DESCRIPTION="All-In-One Solution for Remote Access and Support over the Internet"
|
||||
HOMEPAGE="https://www.teamviewer.com"
|
||||
MY_URI="https://dl.teamviewer.com/download/linux/version_${MY_MAJOR}x/${PN}_${PV}"
|
||||
SRC_URI="
|
||||
amd64? ( ${MY_URI}_amd64.tar.xz )
|
||||
arm? ( ${MY_URI}_armhf.tar.xz )
|
||||
arm64? ( ${MY_URI}_arm64.tar.xz )
|
||||
x86? ( ${MY_URI}_i386.tar.xz )"
|
||||
S="${WORKDIR}"/teamviewer
|
||||
|
||||
LICENSE="TeamViewer MIT"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
|
||||
RESTRICT="bindist mirror strip"
|
||||
|
||||
# Unpack will fail without app-arch/xz-utils[extra-filters], bug #798027
|
||||
BDEPEND="app-arch/xz-utils[extra-filters(+)]"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/glib:2
|
||||
dev-libs/nspr
|
||||
dev-libs/nss
|
||||
media-libs/fontconfig
|
||||
media-libs/freetype
|
||||
media-libs/libglvnd[X]
|
||||
sys-apps/dbus
|
||||
sys-apps/util-linux
|
||||
sys-libs/glibc
|
||||
sys-libs/zlib:0/1[minizip]
|
||||
x11-libs/libICE
|
||||
x11-libs/libSM
|
||||
x11-libs/libX11
|
||||
x11-libs/libXScrnSaver
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXcursor
|
||||
x11-libs/libXdamage
|
||||
x11-libs/libXext
|
||||
x11-libs/libXfixes
|
||||
x11-libs/libXi
|
||||
x11-libs/libXrandr
|
||||
x11-libs/libXrender
|
||||
x11-libs/libXtst
|
||||
x11-libs/libxcb
|
||||
"
|
||||
# For consolekit incompatibility see https://forums.gentoo.org/viewtopic-p-8332956.html#8332956
|
||||
|
||||
QA_PREBUILT="opt/${MY_P}/*"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# Switch operation mode from 'portable' to 'installed'
|
||||
sed -e "s/TAR_NI/TAR_IN/g" -i tv_bin/script/tvw_config || die
|
||||
|
||||
sed -i \
|
||||
-e "/^ExecStart/s|${PN}|${MY_P}|" \
|
||||
-e "/^PIDFile/s|/var/run/|/run/|" \
|
||||
tv_bin/script/teamviewerd.service || die
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local dst="/opt/${MY_P}" # install destination
|
||||
|
||||
insinto ${dst}
|
||||
doins -r tv_bin
|
||||
|
||||
# Set permissions for executables and libraries
|
||||
local exe
|
||||
for exe in $(find tv_bin -type f -executable -or -name '*.so' || die); do
|
||||
fperms +x ${dst}/${exe}
|
||||
done
|
||||
|
||||
newinitd "${FILESDIR}"/teamviewerd15.init teamviewerd
|
||||
systemd_dounit tv_bin/script/teamviewerd.service
|
||||
|
||||
insinto /usr/share/dbus-1/services
|
||||
doins tv_bin/script/com.teamviewer.TeamViewer.service
|
||||
doins tv_bin/script/com.teamviewer.TeamViewer.Desktop.service
|
||||
|
||||
insinto /usr/share/polkit-1/actions
|
||||
doins tv_bin/script/com.teamviewer.TeamViewer.policy
|
||||
|
||||
local size
|
||||
for size in 16 24 32 48 256; do
|
||||
newicon -s ${size} tv_bin/desktop/teamviewer_${size}.png teamviewer.png
|
||||
done
|
||||
|
||||
dodoc -r doc
|
||||
|
||||
# Make docs available in expected location
|
||||
dosym ../../usr/share/doc/${PF}/doc ${dst}/doc
|
||||
|
||||
# We need to keep docs uncompressed, bug #778617
|
||||
docompress -x /usr/share/doc/${PF}/.
|
||||
|
||||
keepdir /etc/${MY_P}
|
||||
dosym ../../etc/${MY_P} ${dst}/config
|
||||
|
||||
# Create directory and symlink for log files (NOTE: according to Team-
|
||||
# Viewer devs, all paths are hard-coded in the binaries; therefore
|
||||
# using the same path as the DEB/RPM archives, i.e. '/var/log/teamviewer
|
||||
# <major-version>')
|
||||
keepdir /var/log/${MY_P}
|
||||
dosym ../../var/log/${MY_P} ${dst}/logfiles
|
||||
|
||||
dodir /opt/bin
|
||||
dosym ${dst}/tv_bin/teamviewerd /opt/bin/teamviewerd
|
||||
dosym ${dst}/tv_bin/script/teamviewer /opt/bin/teamviewer
|
||||
|
||||
make_desktop_entry teamviewer "TeamViewer ${MY_MAJOR}"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
|
||||
ewarn
|
||||
ewarn "Please note that the teamviewer gui works only when started from"
|
||||
ewarn "a session initiated by a display manager." #799137
|
||||
optfeature_header "Install one of the following display managers:"
|
||||
optfeature "an example display manager" x11-misc/cdm gnome-base/gdm gui-apps/gtkgreet x11-misc/lightdm \
|
||||
lxde-base/lxdm sys-apps/qingy x11-misc/sddm x11-misc/slim x11-misc/wdm x11-apps/xdm
|
||||
|
||||
if [[ -z ${REPLACING_VERSIONS} ]]; then
|
||||
elog
|
||||
elog "Please note that parallel installation of multiple versions of"
|
||||
elog "TeamViewer is currently not supported at runtime. Bug #621818"
|
||||
elog
|
||||
elog "Before using TeamViewer, you need to start its daemon:"
|
||||
elog "OpenRC:"
|
||||
elog "# /etc/init.d/teamviewerd start"
|
||||
elog "# rc-update add teamviewerd default"
|
||||
elog
|
||||
elog "Systemd:"
|
||||
elog "# systemctl start teamviewerd.service"
|
||||
elog "# systemctl enable teamviewerd.service"
|
||||
elog
|
||||
elog "To display additional command line options simply run:"
|
||||
elog "$ teamviewer help"
|
||||
elog
|
||||
elog "Most likely TeamViewer will work normally only on systems with systemd"
|
||||
elog "or elogind. See this thread for additional info:"
|
||||
elog "https://forums.gentoo.org/viewtopic-p-8332956.html#8332956"
|
||||
fi
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user